Version bump wrt #218921

(Portage version: 2.1.5_rc6)

3 files changed, 82 insertions, 4 deletions

diff --git a/app-misc/mc/ChangeLog b/app-misc/mc/ChangeLog
index 1e0ee3fabc4a..6cd5d2d496ac 100644
--- a/app-misc/mc/ChangeLog
+++ b/app-misc/mc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/mc
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.137 2008/03/01 14:02:55 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.138 2008/04/27 08:57:39 drac Exp $
+
+*mc-4.6.2_pre1 (27 Apr 2008)
+
+  27 Apr 2008; Samuli Suominen <drac@gentoo.org> +mc-4.6.2_pre1.ebuild:
+  Version bump wrt #218921 with patchset.
 
   01 Mar 2008; Diego Pettenò <flameeyes@gentoo.org> mc-4.6.1-r3.ebuild,
   mc-4.6.1-r4.ebuild:
@@ -8,7 +13,7 @@
   installed anymore.
 
   09 Feb 2008; Samuli Suominen <drac@gentoo.org> mc-4.6.1-r4.ebuild:
-  Fix mc to work with slang 2.1.3.
+  Change slang dep. to allow 2.1.3.
 
   19 Nov 2007; Joshua Kinard <kumba@gentoo.org> mc-4.6.1-r4.ebuild:
   Stable on mips, per #197144.
diff --git a/app-misc/mc/mc-4.6.1-r4.ebuild b/app-misc/mc/mc-4.6.1-r4.ebuild
index 5f0daf4611c1..00b96436caa8 100644
--- a/app-misc/mc/mc-4.6.1-r4.ebuild
+++ b/app-misc/mc/mc-4.6.1-r4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.6.1-r4.ebuild,v 1.13 2008/03/01 14:02:55 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.6.1-r4.ebuild,v 1.14 2008/04/27 08:57:39 drac Exp $
 
 inherit flag-o-matic eutils
 
@@ -14,7 +14,7 @@ SRC_URI="http://www.ibiblio.org/pub/Linux/utils/file/managers/${PN}/${P}.tar.gz
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="alpha amd64 arm hppa ia64 mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd"
 IUSE="7zip X gpm ncurses nls samba slang unicode"
 
 RDEPEND="kernel_linux? ( >=sys-fs/e2fsprogs-1.19 )
diff --git a/app-misc/mc/mc-4.6.2_pre1.ebuild b/app-misc/mc/mc-4.6.2_pre1.ebuild
new file mode 100644
index 000000000000..f78a601e2b52
--- /dev/null
+++ b/app-misc/mc/mc-4.6.2_pre1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.6.2_pre1.ebuild,v 1.1 2008/04/27 08:57:39 drac Exp $
+
+inherit eutils
+
+MY_P=${P/_/-}
+
+DESCRIPTION="GNU Midnight Commander is a s-lang based file manager."
+HOMEPAGE="http://www.gnu.org/software/mc"
+SRC_URI="http://ftp.gnu.org/gnu/mc/${MY_P}.tar.gz
+	http://dev.gentoo.org/~drac/${P}-patchset-1.tbz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="gpm nls samba X"
+
+RDEPEND=">=dev-libs/glib-2
+	>=sys-libs/slang-2.1.3
+	gpm? ( sys-libs/gpm )
+	X? ( x11-libs/libX11
+		x11-libs/libICE
+		x11-libs/libXau
+		x11-libs/libXdmcp
+		x11-libs/libSM )
+	samba? ( net-fs/samba )
+	kernel_linux? ( sys-fs/e2fsprogs )
+	app-arch/zip
+	app-arch/unzip"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${WORKDIR}"/patches/*.patch
+
+	# Prevent lazy bindings in cons.saver binary wrt bug #135009
+	sed -i -e "s:^\(cons_saver_LDADD = .*\):\1 -Wl,-z,now:" \
+		src/Makefile.in || die "sed failed."
+}
+
+src_compile() {
+	# Default is slang for unicode in Gentoo (which is also upstream default)
+	local myconf="--with-vfs --with-ext2undel --with-edit --enable-charset --with-screen=slang"
+
+	if use samba; then
+		myconf+=" --with-samba --with-configdir=/etc/samba --with-codepagedir=/var/lib/samba/codepages"
+	else
+		myconf+=" --without-samba"
+	fi
+
+	econf --disable-dependency-tracking \
+		$(use_enable nls) \
+		$(use_with gpm gpm-mouse) \
+		$(use_with X x) \
+		${myconf}
+
+	emake || die "emake failed."
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dodoc AUTHORS FAQ HACKING MAINTAINERS NEWS README* TODO
+
+	# Install ebuild syntax
+	insinto /usr/share/mc/syntax
+	doins "${FILESDIR}"/ebuild.syntax
+}