Bump

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 60 insertions, 1 deletions

diff --git a/dev-python/py-amqp/ChangeLog b/dev-python/py-amqp/ChangeLog
index 05b6ade38210..61ff99457a0e 100644
--- a/dev-python/py-amqp/ChangeLog
+++ b/dev-python/py-amqp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/py-amqp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/ChangeLog,v 1.5 2013/03/13 17:39:10 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/ChangeLog,v 1.6 2013/04/16 08:21:38 patrick Exp $
+
+*py-amqp-1.0.11 (16 Apr 2013)
+
+  16 Apr 2013; Patrick Lauer <patrick@gentoo.org> +py-amqp-1.0.11.ebuild:
+  Bump
 
 *py-amqp-1.0.9 (13 Mar 2013)
 
diff --git a/dev-python/py-amqp/py-amqp-1.0.11.ebuild b/dev-python/py-amqp/py-amqp-1.0.11.ebuild
new file mode 100644
index 000000000000..6d71347c56b2
--- /dev/null
+++ b/dev-python/py-amqp/py-amqp-1.0.11.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/py-amqp-1.0.11.ebuild,v 1.1 2013/04/16 08:21:38 patrick Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2} pypy{1_9,2_0} )
+
+inherit distutils-r1
+
+MY_PN="amqp"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
+HOMEPAGE="https://github.com/celery/py-amqp http://pypi.python.org/pypi/amqp/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples extras test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.0.6_disable_socket_tests.patch )
+
+python_test() {
+	cp -r -l funtests "${BUILD_DIR}"/lib/ || die
+	cd "${BUILD_DIR}"/lib || die
+	if [[ ${EPYTHON:6:1} == 3 ]]; then
+		# Notes:
+		#   -W is not supported by python3.1
+		#   -n causes Python to write into hardlinked files
+		2to3 --no-diffs -w funtests || die
+	fi
+	"${PYTHON}" funtests/run_all.py || ewarn "Tests fail with ${EPYTHON}"
+	rm -rf funtests/ || die
+}
+
+python_install_all() {
+	dodoc -r docs/.
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		docinto examples
+		dodoc -r demo/.
+	fi
+	if use extras; then
+		insinto /usr/share/${PF}
+		doins -r extra
+	fi
+}