Revision bump: EAPI 5, migrate to python-r1 eclass, add epatch_user

(Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

2 files changed, 58 insertions, 1 deletions

diff --git a/media-gfx/cropgui/ChangeLog b/media-gfx/cropgui/ChangeLog
index 308edfed771c..126b705b12a4 100644
--- a/media-gfx/cropgui/ChangeLog
+++ b/media-gfx/cropgui/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/cropgui
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/cropgui/ChangeLog,v 1.4 2013/05/28 20:00:46 qnikst Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/cropgui/ChangeLog,v 1.5 2013/05/29 13:16:15 pinkbyte Exp $
+
+*cropgui-0.1.1-r2 (29 May 2013)
+
+  29 May 2013; Sergey Popov <pinkbyte@gentoo.org> +cropgui-0.1.1-r2.ebuild:
+  Revision bump: EAPI 5, migrate to python-r1 eclass, add epatch_user
 
 *cropgui-0.1.1-r1 (28 May 2013)
 
diff --git a/media-gfx/cropgui/cropgui-0.1.1-r2.ebuild b/media-gfx/cropgui/cropgui-0.1.1-r2.ebuild
new file mode 100644
index 000000000000..efe3dfd8596d
--- /dev/null
+++ b/media-gfx/cropgui/cropgui-0.1.1-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/cropgui/cropgui-0.1.1-r2.ebuild,v 1.1 2013/05/29 13:16:15 pinkbyte Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_{6,7} )
+inherit eutils python-r1
+
+DESCRIPTION="GUI for lossless cropping of jpeg images"
+HOMEPAGE="http://emergent.unpythonic.net/01248401946"
+SRC_URI="http://media.unpythonic.net/emergent-files/01248401946/${PN}_${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${PYTHON_DEPS}
+	dev-python/imaging[${PYTHON_USEDEP}]
+	dev-python/pygobject:2[${PYTHON_USEDEP}]
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	sed -i  -e '/Encoding/d' \
+		-e '/Version/d' \
+		-e '/MimeType/s/$/&;/' \
+		-e '/Categories/s/Application;//' \
+		cropgui.desktop || die 'sed on cropgui.desktop failed'
+	# bug 471530
+	epatch "${FILESDIR}/${P}-PIL.patch"
+
+	epatch_user
+}
+
+install_cropgui_wrapper() {
+	python_domodule cropgtk.py cropgui_common.py filechooser.py cropgui.glade
+	make_wrapper "${PN}-${EPYTHON}" "${PYTHON} $(python_get_sitedir)/${PN}/cropgtk.py"
+}
+
+src_install() {
+	local python_moduleroot="${PN}"
+	python_foreach_impl install_cropgui_wrapper
+	dosym python-exec /usr/bin/"${PN}"
+
+	domenu "${PN}.desktop"
+	doicon "${PN}.png"
+}