Fix broken glib version check that prevented conversion from .svg to .png wrt #468050 by Lars Wendler, Nikolaj Sjujskij and Andrian Nord

(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 176 insertions, 1 deletions

diff --git a/media-gfx/imagemagick/ChangeLog b/media-gfx/imagemagick/ChangeLog
index 048f6e8b6ba9..a62fc8322854 100644
--- a/media-gfx/imagemagick/ChangeLog
+++ b/media-gfx/imagemagick/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-gfx/imagemagick
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.510 2013/08/29 19:52:19 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.511 2013/08/31 19:17:05 ssuominen Exp $
+
+*imagemagick-6.8.6.8-r1 (31 Aug 2013)
+
+  31 Aug 2013; Samuli Suominen <ssuominen@gentoo.org>
+  +files/imagemagick-6.8.6.8-broken_glib_version_check.patch.patch,
+  +imagemagick-6.8.6.8-r1.ebuild:
+  Fix broken glib version check that prevented conversion from .svg to .png wrt
+  #468050 by  Lars Wendler, Nikolaj Sjujskij and Andrian Nord
 
   29 Aug 2013; Agostino Sarubbo <ago@gentoo.org> imagemagick-6.8.6.8.ebuild:
   Stable for ia64, wrt bug #481146
diff --git a/media-gfx/imagemagick/files/imagemagick-6.8.6.8-broken_glib_version_check.patch.patch b/media-gfx/imagemagick/files/imagemagick-6.8.6.8-broken_glib_version_check.patch.patch
new file mode 100644
index 000000000000..0e994ddbbb07
--- /dev/null
+++ b/media-gfx/imagemagick/files/imagemagick-6.8.6.8-broken_glib_version_check.patch.patch
@@ -0,0 +1,15 @@
+http://bugs.gentoo.org/468050
+
+(Still broken at upstream ImageMagick 6.8.6-9, SVN 13087)
+
+--- coders/svg.c
++++ coders/svg.c
+@@ -3216,7 +3216,7 @@
+   (void) CopyMagickString(version,"XML " LIBXML_DOTTED_VERSION,MaxTextExtent);
+ #endif
+ #if defined(MAGICKCORE_RSVG_DELEGATE)
+-#if !GLIB_CHECK_VERSION(2,5,0)
++#if !GLIB_CHECK_VERSION(2,35,0)
+   g_type_init();
+ #endif
+   (void) FormatLocaleString(version,MaxTextExtent,"RSVG %d.%d.%d",
diff --git a/media-gfx/imagemagick/imagemagick-6.8.6.8-r1.ebuild b/media-gfx/imagemagick/imagemagick-6.8.6.8-r1.ebuild
new file mode 100644
index 000000000000..02f4095490c9
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.8.6.8-r1.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/imagemagick-6.8.6.8-r1.ebuild,v 1.1 2013/08/31 19:17:05 ssuominen Exp $
+
+EAPI=5
+inherit multilib toolchain-funcs versionator libtool flag-o-matic eutils
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/jasper )
+	lcms? ( media-libs/lcms:2 )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8 )
+	png? ( media-libs/libpng:0 )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0 )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2 )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-broken_glib_version_check.patch.patch #468050
+	elibtoolize # for Darwin modules
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+	use q64 && depth=64
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k jp2) \
+		--without-lcms \
+		$(use_with lcms lcms2) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp
+}
+
+src_test() {
+	if has_version ~${CATEGORY}/${P}; then
+		emake -j1 check
+	else
+		ewarn "Skipping testsuite because installed version doesn't match."
+	fi
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}