media-libs/babl: 9999

(Portage version: 2.1.10.56/cvs/Linux x86_64)

2 files changed, 58 insertions, 1 deletions

diff --git a/media-libs/babl/ChangeLog b/media-libs/babl/ChangeLog
index 42a150d0378d..925485048e00 100644
--- a/media-libs/babl/ChangeLog
+++ b/media-libs/babl/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/babl
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/babl/ChangeLog,v 1.40 2012/05/05 08:02:35 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/babl/ChangeLog,v 1.41 2012/05/17 18:50:59 sping Exp $
+
+*babl-9999 (17 May 2012)
+
+  17 May 2012; Sebastian Pipping <sping@gentoo.org> +babl-9999.ebuild:
+  Adding live ebuild for and by xmw (bug #416337)
 
   05 May 2012; Jeff Horelick <jdhore@gentoo.org> babl-0.1.4.ebuild,
   babl-0.1.4-r2.ebuild, babl-0.1.6.ebuild, babl-0.1.8.ebuild,
diff --git a/media-libs/babl/babl-9999.ebuild b/media-libs/babl/babl-9999.ebuild
new file mode 100644
index 000000000000..7802c1f9dbe7
--- /dev/null
+++ b/media-libs/babl/babl-9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/babl/babl-9999.ebuild,v 1.1 2012/05/17 18:50:59 sping Exp $
+
+EAPI=4
+VALASLOT=0.14
+EGIT_REPO_URI="git://git.gnome.org/babl"
+
+inherit autotools eutils git-2
+
+DESCRIPTION="A dynamic, any to any, pixel format conversion library"
+HOMEPAGE="http://www.gegl.org/babl/"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS=""
+IUSE="altivec +introspection sse mmx vala"
+
+RDEPEND="introspection? ( >=dev-libs/gobject-introspection-0.10 )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2
+	vala? ( dev-lang/vala:${VALASLOT}[vapigen] )
+	virtual/pkgconfig"
+
+src_prepare() {
+	# fix compilation on OSX, can be dropped on next release:
+	# http://mail.gnome.org/archives/commits-list/2012-April/msg02589.html
+	sed -i -e 's/values\.h/limits.h/' babl/babl-palette.c || die
+	eautoreconf
+}
+
+src_configure() {
+	# Automagic rsvg support is just for website generation we do not call,
+	#     so we don't need to fix it
+	# w3m is used for dist target thus no issue for us that it is automagically
+	#     detected
+	VAPIGEN="$(type -p vapigen-${VALASLOT})" \
+	econf \
+		--disable-static \
+		--disable-maintainer-mode \
+		$(use_enable altivec) \
+		$(use_enable introspection) \
+		$(use_enable mmx) \
+		$(use_enable sse) \
+		$(use_with vala)
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	find "${ED}" -name '*.la' -delete
+	dodoc AUTHORS MAINTAINERS NEWS TODO
+}