1 files changed, 69 insertions, 0 deletions
diff --git a/net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r2.ebuild b/net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r2.ebuild
new file mode 100644
index 000000000000..5b013ba00994
--- /dev/null
+++ b/net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.3-r2.ebuild,v 1.1 2014/09/30 16:03:10 jlec Exp $
+
+EAPI=5
+
+inherit cmake-utils systemd
+
+MY_PN=openvassd
+
+DESCRIPTION="A remote security scanner for Linux (OpenVAS-scanner)"
+HOMEPAGE="http://www.openvas.org/"
+SRC_URI="http://wald.intevation.org/frs/download.php/1726/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE=""
+
+RDEPEND="
+	>=net-analyzer/openvas-libraries-7.0.4
+	!net-analyzer/openvas-plugins
+	!net-analyzer/openvas-server"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-util/cmake"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-bsdsource.patch
+	"${FILESDIR}"/${P}-mkcertclient.patch
+	"${FILESDIR}"/${P}-rulesdir.patch
+	"${FILESDIR}"/${P}-run.patch
+	)
+
+src_prepare() {
+	sed \
+		-e '/^install.*OPENVAS_CACHE_DIR.*/d' \
+		-i CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=( -DLOCALSTATEDIR=/var -DSYSCONFDIR=/etc )
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newinitd "${FILESDIR}"/${MY_PN}.init ${MY_PN}
+
+	insinto /etc/openvas
+	doins "${FILESDIR}"/${MY_PN}.conf "${FILESDIR}"/${MY_PN}-daemon.conf
+	dosym ../openvas/${MY_PN}-daemon.conf /etc/conf.d/${PN}
+
+	insinto /etc/logrotate.d
+	doins "${FILESDIR}"/${MY_PN}.logrotate
+
+	dodoc "${FILESDIR}"/openvas-nvt-sync-cron
+
+	systemd_newtmpfilesd "${FILESDIR}"/${MY_PN}.tmpfiles.d ${MY_PN}.conf
+	systemd_dounit "${FILESDIR}"/${MY_PN}.service
+}
+
+pkg_postinst() {
+	elog "To use ${MY_PN}, you first need to:"
+	elog "1. Call 'openvas-nvt-sync' to download/update plugins"
+	elog "2. Call 'openvas-mkcert' to generate a server certificate"
+}