1 files changed, 42 insertions, 0 deletions
diff --git a/sys-apps/less/less-424.ebuild b/sys-apps/less/less-424.ebuild
new file mode 100644
index 000000000000..dde00e0d5361
--- /dev/null
+++ b/sys-apps/less/less-424.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/less-424.ebuild,v 1.1 2009/02/09 18:58:35 vapier Exp $
+
+inherit eutils
+
+DESCRIPTION="Excellent text file viewer"
+HOMEPAGE="http://www.greenwoodsoftware.com/less/"
+SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz
+	http://www-zeuthen.desy.de/~friebel/unix/less/code2color"
+
+LICENSE="|| ( GPL-3 less )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="unicode"
+
+DEPEND=">=sys-libs/ncurses-5.2"
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cd "${S}"
+	cp "${DISTDIR}"/code2color "${S}"/
+	epatch "${FILESDIR}"/code2color.patch
+}
+
+yesno() { use $1 && echo yes || echo no ; }
+src_compile() {
+	export ac_cv_lib_ncursesw_initscr=$(yesno unicode)
+	export ac_cv_lib_ncurses_initscr=$(yesno !unicode)
+	econf || die
+	emake || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+
+	dobin code2color || die "dobin"
+	newbin "${FILESDIR}"/lesspipe.sh lesspipe.sh || die "newbin"
+	newenvd "${FILESDIR}"/less.envd 70less
+
+	dodoc NEWS README* "${FILESDIR}"/README.Gentoo
+}