From 2713f05a545adf67f99571c01dfe861f07aa60c7 Mon Sep 17 00:00:00 2001
From: Christoph Junghans <ottxor@gentoo.org>
Date: Fri, 17 Jun 2011 08:57:14 +0000
Subject: [sci-chemistry/votca-csg] version bump

(Portage version: 2.1.9.42/cvs/Linux i686)
---
 sci-chemistry/votca-csg/ChangeLog            |  8 ++-
 sci-chemistry/votca-csg/metadata.xml         |  1 +
 sci-chemistry/votca-csg/votca-csg-1.2.ebuild | 78 ++++++++++++++++++++++++++++
 3 files changed, 86 insertions(+), 1 deletion(-)
 create mode 100644 sci-chemistry/votca-csg/votca-csg-1.2.ebuild

(limited to 'sci-chemistry/votca-csg')

diff --git a/sci-chemistry/votca-csg/ChangeLog b/sci-chemistry/votca-csg/ChangeLog
index e6a940fb7680..537fa0a6034b 100644
--- a/sci-chemistry/votca-csg/ChangeLog
+++ b/sci-chemistry/votca-csg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-chemistry/votca-csg
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/votca-csg/ChangeLog,v 1.4 2011/04/04 20:05:31 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/votca-csg/ChangeLog,v 1.5 2011/06/17 08:57:14 ottxor Exp $
+
+*votca-csg-1.2 (17 Jun 2011)
+
+  17 Jun 2011; Christoph Junghans <ottxor@gentoo.org> +votca-csg-1.2.ebuild,
+  metadata.xml:
+  Version bump
 
 *votca-csg-1.1.2 (04 Apr 2011)
 
diff --git a/sci-chemistry/votca-csg/metadata.xml b/sci-chemistry/votca-csg/metadata.xml
index 4664d891702f..7daef59af41e 100644
--- a/sci-chemistry/votca-csg/metadata.xml
+++ b/sci-chemistry/votca-csg/metadata.xml
@@ -7,6 +7,7 @@
 		<name>Christoph Junghans</name>
 	</maintainer>
 	<use>
+		<flag name='boost'>Compile against external boost headers (dev-libs/boost)</flag>
 		<flag name='gromacs'>Add support for file formats from <pkg>sci-chemistry/gromacs</pkg></flag>
 	</use>
 </pkgmetadata>
diff --git a/sci-chemistry/votca-csg/votca-csg-1.2.ebuild b/sci-chemistry/votca-csg/votca-csg-1.2.ebuild
new file mode 100644
index 000000000000..b504ffd54cae
--- /dev/null
+++ b/sci-chemistry/votca-csg/votca-csg-1.2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/votca-csg/votca-csg-1.2.ebuild,v 1.1 2011/06/17 08:57:14 ottxor Exp $
+
+EAPI="3"
+
+inherit cmake-utils bash-completion
+
+MANUAL_PV=1.2
+if [ "${PV}" != "9999" ]; then
+	SRC_URI="http://votca.googlecode.com/files/${PF}.tar.gz
+		doc? ( http://votca.googlecode.com/files/votca-manual-${MANUAL_PV}.pdf )"
+	RESTRICT="primaryuri"
+else
+	SRC_URI=""
+	inherit mercurial
+	EHG_REPO_URI="https://csg.votca.googlecode.com/hg"
+	EHG_REVISION="default"
+	S="${WORKDIR}/${EHG_REPO_URI##*/}"
+	PDEPEND="doc? ( =app-doc/votca-csg-manual-${PV} )"
+fi
+
+DESCRIPTION="Votca coarse-graining engine"
+HOMEPAGE="http://www.votca.org"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="-boost doc +gromacs"
+
+RDEPEND="=sci-libs/votca-tools-${PV}[boost=]
+	gromacs? ( sci-chemistry/gromacs )
+	dev-lang/perl
+	app-shells/bash"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen[-nodot] )
+	>=app-text/txt2tags-2.5
+	dev-util/pkgconfig"
+
+src_configure() {
+	local extra="-DWITH_GMX_DEVEL=OFF"
+
+	use gromacs && has_version =sci-chemistry/gromacs-9999 && \
+		extra="-DWITH_GMX_DEVEL=ON"
+
+	mycmakeargs=(
+		$(cmake-utils_use boost EXTERNAL_BOOST)
+		$(cmake-utils_use_with gromacs GMX)
+		${extra}
+		-DWITH_RC_FILES=OFF
+	)
+	cmake-utils_src_configure || die
+}
+
+src_install() {
+	DOCS=(README NOTICE ${CMAKE_BUILD_DIR}/CHANGELOG)
+	dobashcompletion scripts/csg-completion.bash ${PN} || die
+	cmake-utils_src_install || die
+	if use doc; then
+		if [ -n "${PV##*9999}" ]; then
+			dodoc "${DISTDIR}/votca-manual-${MANUAL_PV}.pdf" || die
+		fi
+		cd "${CMAKE_BUILD_DIR}" || die
+		cd share/doc || die
+		doxygen || die
+		dohtml -r html/* || die
+	fi
+}
+
+pkg_postinst() {
+	elog
+	elog "Please read and cite:"
+	elog "VOTCA, J. Chem. Theory Comput. 5, 3211 (2009). "
+	elog "http://dx.doi.org/10.1021/ct900369w"
+	elog
+	bash-completion_pkg_postinst
+}
-- 
cgit v1.2.3-65-gdbad