From 3e9984ddc7d92ded0be1bd245b764038bf8a8bb2 Mon Sep 17 00:00:00 2001
From: Alexandre Rostovtsev <tetromino@gentoo.org>
Date: Fri, 20 Apr 2012 08:03:40 +0000
Subject: Version bump, fixes a memory leak.

(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)
---
 x11-libs/vte/ChangeLog         |  7 ++++-
 x11-libs/vte/vte-0.32.1.ebuild | 59 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+), 1 deletion(-)
 create mode 100644 x11-libs/vte/vte-0.32.1.ebuild

(limited to 'x11-libs/vte')

diff --git a/x11-libs/vte/ChangeLog b/x11-libs/vte/ChangeLog
index 789de4a3ca08..f818e653effd 100644
--- a/x11-libs/vte/ChangeLog
+++ b/x11-libs/vte/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/vte
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.319 2012/04/19 20:47:48 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.320 2012/04/20 08:03:40 tetromino Exp $
+
+*vte-0.32.1 (20 Apr 2012)
+
+  20 Apr 2012; Alexandre Rostovtsev <tetromino@gentoo.org> +vte-0.32.1.ebuild:
+  Version bump, fixes a memory leak.
 
   19 Apr 2012; Brent Baude <ranger@gentoo.org> vte-0.28.2-r203.ebuild:
   Marking vte-0.28.2-r203 ppc64 stable for bug 410611
diff --git a/x11-libs/vte/vte-0.32.1.ebuild b/x11-libs/vte/vte-0.32.1.ebuild
new file mode 100644
index 000000000000..de095b10c83a
--- /dev/null
+++ b/x11-libs/vte/vte-0.32.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.32.1.ebuild,v 1.1 2012/04/20 08:03:40 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="GNOME terminal widget"
+HOMEPAGE="http://git.gnome.org/browse/vte"
+
+LICENSE="LGPL-2"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc glade +introspection"
+
+PDEPEND="x11-libs/gnome-pty-helper"
+RDEPEND=">=dev-libs/glib-2.31.13:2
+	>=x11-libs/gtk+-3.1.9:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	sys-devel/gettext
+	doc? ( >=dev-util/gtk-doc-1.13 )"
+
+pkg_setup() {
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	# Do not disable gnome-pty-helper, bug #401389
+	G2CONF="${G2CONF}
+		--disable-deprecation
+		--disable-static
+		$(use_enable debug)
+		$(use_enable glade glade-catalogue)
+		$(use_enable introspection)"
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+}
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=663779
+	epatch "${FILESDIR}/${PN}-0.30.1-alt-meta.patch"
+
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	rm -v "${ED}usr/libexec/gnome-pty-helper" || die
+}
-- 
cgit v1.2.3-65-gdbad