# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/pacparser/pacparser-1.3.1.ebuild,v 1.1 2013/11/26 05:29:31 bicatali Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit eutils python-r1 multilib

DESCRIPTION="Library to parse proxy auto-config files"
HOMEPAGE="http://code.google.com/p/pacparser/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc python"

DEPEND="python? ( ${PYTHON_DEPS} )"
RDEPEND="${DEPEND}"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

# spidermonkey-1.7.0 is bundled
# tested unbundling with spidermonkey-1.8* and 17
# failures : unbundling not worth

src_prepare() {
	epatch "${FILESDIR}"/${P}-makefile.patch
	export NO_INTERNET=yes
}

src_compile() {
	emake -C src
	use python && python_foreach_impl emake -C src pymod
}

src_test() {
	emake -C src testpactester
	use python && emake -C src test-pymod
}

src_install() {
	emake DESTDIR="${D}" LIB_PREFIX="${D}/usr/$(get_libdir)" -C src install
	dodoc README
	use python && python_foreach_impl \
		emake DESTDIR="${D}" \
		LIB_PREFIX="${D}/usr/$(get_libdir)" -C src install-pymod
	use doc && emake DESTDIR="${D}" \
		DOC_PREFIX="${D}/usr/share/doc/${PF}" -C src install-docs
}