dev-util/devhelp/devhelp-0.14.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/devhelp-0.14.ebuild,v 1.2 2007/05/19 21:48:44 dang Exp $

inherit toolchain-funcs gnome2

DESCRIPTION="An API documentation browser for GNOME 2"
HOMEPAGE="http://developer.imendio.com/wiki/Devhelp"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="seamonkey xulrunner zlib"

RDEPEND=">=gnome-base/gconf-2.6
	>=x11-libs/gtk+-2.8
	>=dev-libs/glib-2.8
	>=gnome-base/libglade-2.4
	>=x11-libs/libwnck-2.10
	sparc? ( >=www-client/mozilla-firefox-1.0.2-r1 )
	|| (
		xulrunner? ( net-libs/xulrunner )
		seamonkey? ( >=www-client/seamonkey-1 )
		>=www-client/mozilla-firefox-1.0.2-r1
	)
	zlib? ( sys-libs/zlib )"

DEPEND="${RDEPEND}
	  sys-devel/gettext
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.9"

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	G2CONF="$(use_with zlib)"

	if use xulrunner ; then
		G2CONF="${G2CONF} --with-gecko=xulrunner"
	elif use seamonkey ; then
		G2CONF="${G2CONF} --with-gecko=seamonkey"
	else
		G2CONF="${G2CONF} --with-gecko=firefox"
	fi

	# ICC is crazy, silence warnings (bug #154010)
	if [[ $(tc-getCC) == "icc" ]] ; then
		G2CONF="${G2CONF} --with-compile-warnings=no"
	fi
}