From eef73c3979a26f8320087262664b33065e802185 Mon Sep 17 00:00:00 2001
From: Sobhan Mohammadpour <sobhan@gentoo.org>
Date: Thu, 28 Feb 2019 18:19:13 +0330
Subject: app-editors/latexila:  fix minor problems

add slot to libxml2, move vala_depend to depend	and add	glib-utils to DEPEND

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Manifest-Sign-Key: 0x7DF238CF0AA182E1
Signed-off-by: Sobhan Mohammadpour <sobhan@gentoo.org>
---
 app-editors/latexila/latexila-3.30.2-r1.ebuild | 71 ++++++++++++++++++++++++++
 app-editors/latexila/latexila-3.30.2.ebuild    | 70 -------------------------
 2 files changed, 71 insertions(+), 70 deletions(-)
 create mode 100644 app-editors/latexila/latexila-3.30.2-r1.ebuild
 delete mode 100644 app-editors/latexila/latexila-3.30.2.ebuild

diff --git a/app-editors/latexila/latexila-3.30.2-r1.ebuild b/app-editors/latexila/latexila-3.30.2-r1.ebuild
new file mode 100644
index 00000000..0b072029
--- /dev/null
+++ b/app-editors/latexila/latexila-3.30.2-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_MIN_API_VERSION="0.34"
+VALA_USE_DEPEND="vapigen"
+GNOME_ORG_MODULE="gnome-latex"
+
+inherit gnome2 vala
+
+DESCRIPTION="Integrated LaTeX environment for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/LaTeXila"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection +latexmk rubber"
+
+COMMON_DEPEND="
+	app-text/enchant
+	>=app-text/gspell-1.8:0=
+	>=dev-libs/glib-2.56:2[dbus]
+	>=dev-libs/libgee-0.10:0.8=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/gtksourceview:4=
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	>=x11-libs/tepl-4.2:4
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	virtual/latex-base
+	x11-themes/hicolor-icon-theme
+	latexmk? ( dev-tex/latexmk )
+	rubber? ( dev-tex/rubber )
+"
+# libxml2+gdk-pixbuf required for glib-compile-resources
+DEPEND="${COMMON_DEPEND}
+	$(vala_depend)
+	app-text/yelp-tools
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.14
+	>=dev-util/intltool-0.50.1
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable introspection)
+}
+
+pkg_postinst() {
+	local v
+	for v in ${REPLACING_VERSIONS}; do
+		if ver_test "3.30.0" -gt ${v}; then
+			ewarn "Latexila has been renamed Gnome LaTeX"
+			ewarn "the binary is now called gnome-latex"
+			break
+		fi
+	done
+
+	gnome2_pkg_postinst
+}
diff --git a/app-editors/latexila/latexila-3.30.2.ebuild b/app-editors/latexila/latexila-3.30.2.ebuild
deleted file mode 100644
index 4fc7c5c1..00000000
--- a/app-editors/latexila/latexila-3.30.2.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-VALA_MIN_API_VERSION="0.34"
-VALA_USE_DEPEND="vapigen"
-GNOME_ORG_MODULE="gnome-latex"
-
-inherit gnome2 vala
-
-DESCRIPTION="Integrated LaTeX environment for GNOME"
-HOMEPAGE="https://wiki.gnome.org/Apps/LaTeXila"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="+introspection +latexmk rubber"
-
-COMMON_DEPEND="
-	$(vala_depend)
-	app-text/enchant
-	>=app-text/gspell-1.8:0=
-	>=dev-libs/glib-2.56:2[dbus]
-	>=dev-libs/libgee-0.10:0.8=
-	gnome-base/gsettings-desktop-schemas
-	>=x11-libs/gtk+-3.22:3
-	x11-libs/gtksourceview:4=
-	x11-libs/gdk-pixbuf:2
-	x11-libs/pango
-	>=x11-libs/tepl-4.2:4
-	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
-"
-RDEPEND="${COMMON_DEPEND}
-	virtual/latex-base
-	x11-themes/hicolor-icon-theme
-	latexmk? ( dev-tex/latexmk )
-	rubber? ( dev-tex/rubber )
-"
-# libxml2+gdk-pixbuf required for glib-compile-resources
-DEPEND="${COMMON_DEPEND}
-	app-text/yelp-tools
-	dev-libs/libxml2
-	dev-util/gdbus-codegen
-	>=dev-util/gtk-doc-am-1.14
-	>=dev-util/intltool-0.50.1
-	virtual/pkgconfig
-"
-
-src_prepare() {
-	gnome2_src_prepare
-	vala_src_prepare
-}
-
-src_configure() {
-	gnome2_src_configure \
-		$(use_enable introspection)
-}
-
-pkg_postinst() {
-	local v
-	for v in ${REPLACING_VERSIONS}; do
-		if ver_test "3.30.0" -gt ${v}; then
-			ewarn "Latexila has been renamed Gnome LaTeX"
-			ewarn "the binary is now called gnome-latex"
-			break
-		fi
-	done
-
-	gnome2_pkg_postinst
-}
-- 
cgit v1.2.3-65-gdbad