From fcf8e12653cb8867d025eecb9993a12b442d238a Mon Sep 17 00:00:00 2001
From: Alexis Ballier <aballier@gentoo.org>
Date: Wed, 7 Sep 2016 12:23:03 +0200
Subject: dev-ml/reactiveData: add live ebuild

Package-Manager: portage-2.3.0
---
 dev-ml/reactiveData/reactiveData-9999.ebuild | 46 ++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-ml/reactiveData/reactiveData-9999.ebuild

(limited to 'dev-ml/reactiveData')

diff --git a/dev-ml/reactiveData/reactiveData-9999.ebuild b/dev-ml/reactiveData/reactiveData-9999.ebuild
new file mode 100644
index 000000000000..59dac4692661
--- /dev/null
+++ b/dev-ml/reactiveData/reactiveData-9999.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+DESCRIPTION="Functional reactive programming with incremental changes in data structures"
+HOMEPAGE="https://github.com/ocsigen/reactiveData"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/ocsigen/reactiveData"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/ocsigen/reactiveData/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3-with-linking-exception"
+SLOT="0/${PV}"
+IUSE="+ocamlopt"
+
+RDEPEND=">=dev-lang/ocaml-3.12:=[ocamlopt?]
+	dev-ml/react:="
+DEPEND="${RDEPEND}
+	dev-ml/findlib
+	dev-ml/opam
+	dev-ml/ocamlbuild
+"
+
+src_compile() {
+	ocaml pkg/build.ml \
+		native=$(usex ocamlopt true false) \
+		native-dynlink=$(usex ocamlopt true false) \
+		|| die
+}
+
+src_install() {
+	opam-installer \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		|| die
+	dodoc README.md
+}
-- 
cgit v1.2.3-65-gdbad