From 0d24f2e36daf9d95d2512a69305e124c3da6fc0d Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Mon, 3 Apr 2023 07:47:55 +0100
Subject: dev-util/ltrace: support libdwfl as unwinder

Add a new USE flag for this (pulling the whole elfutils in if set),
and make it mutually exclusive with unwind because src_configure fails
if both unwinders have been selected.

Closes: https://bugs.gentoo.org/903643
Signed-off-by: Marek Szuba <marecki@gentoo.org>
---
 .../ltrace/ltrace-0.7.91_pre20221216-r1.ebuild     | 63 ++++++++++++++++++++++
 dev-util/ltrace/ltrace-0.7.91_pre20221216.ebuild   | 59 --------------------
 dev-util/ltrace/metadata.xml                       |  1 +
 3 files changed, 64 insertions(+), 59 deletions(-)
 create mode 100644 dev-util/ltrace/ltrace-0.7.91_pre20221216-r1.ebuild
 delete mode 100644 dev-util/ltrace/ltrace-0.7.91_pre20221216.ebuild

(limited to 'dev-util/ltrace')

diff --git a/dev-util/ltrace/ltrace-0.7.91_pre20221216-r1.ebuild b/dev-util/ltrace/ltrace-0.7.91_pre20221216-r1.ebuild
new file mode 100644
index 000000000000..851ee4b9d802
--- /dev/null
+++ b/dev-util/ltrace/ltrace-0.7.91_pre20221216-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+EGIT_COMMIT="5cffc0d2134f697fbac8627ec5b5f0085cd47c8a"
+
+DESCRIPTION="trace library calls made at runtime"
+HOMEPAGE="https://gitlab.com/cespedes/ltrace"
+SRC_URI="https://gitlab.com/cespedes/${PN}/-/archive/${EGIT_COMMIT}.tar.bz2 -> ${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug elfutils selinux test unwind"
+
+REQUIRED_USE="?? ( elfutils unwind )"
+
+RDEPEND="virtual/libelf:=
+	elfutils? ( dev-libs/elfutils )
+	selinux? ( sys-libs/libselinux )
+	unwind? ( sys-libs/libunwind:= )"
+DEPEND="${RDEPEND}
+	sys-libs/binutils-libs
+	test? ( dev-util/dejagnu )"
+
+# Effectively abandoned upstream. Extremely sensitive to the sandbox, versions
+# of core libraries, kernel security settings...
+RESTRICT="test"
+
+S=${WORKDIR}/${PN}-${EGIT_COMMIT}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.7.91-debian-patchset-6.4.patch
+	"${FILESDIR}"/${PN}-0.7.3-CXX-for-tests.patch
+	"${FILESDIR}"/${PN}-0.7.3-alpha-protos.patch
+	"${FILESDIR}"/${PN}-0.7.3-ia64.patch
+	"${FILESDIR}"/${PN}-0.7.3-ia64-pid_t.patch
+	"${FILESDIR}"/${PN}-0.7.3-musl-host.patch
+	"${FILESDIR}"/${PN}-0.7.3-print-test-pie.patch
+	"${FILESDIR}"/${PN}-0.7.91-pid_t.patch
+	"${FILESDIR}"/${PN}-0.7.91-test-glibc-2.33.patch
+	"${FILESDIR}"/${PN}-0.7.91-tuple-tests.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i '/^dist_doc_DATA/d' Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	ac_cv_header_selinux_selinux_h=$(usex selinux) \
+	ac_cv_lib_selinux_security_get_boolean_active=$(usex selinux) \
+	econf \
+		--disable-werror \
+		$(use_enable debug) \
+		$(use_with elfutils) \
+		$(use_with unwind libunwind)
+}
diff --git a/dev-util/ltrace/ltrace-0.7.91_pre20221216.ebuild b/dev-util/ltrace/ltrace-0.7.91_pre20221216.ebuild
deleted file mode 100644
index 24b86f41a73f..000000000000
--- a/dev-util/ltrace/ltrace-0.7.91_pre20221216.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-EGIT_COMMIT="5cffc0d2134f697fbac8627ec5b5f0085cd47c8a"
-
-DESCRIPTION="trace library calls made at runtime"
-HOMEPAGE="https://gitlab.com/cespedes/ltrace"
-SRC_URI="https://gitlab.com/cespedes/${PN}/-/archive/${EGIT_COMMIT}.tar.bz2 -> ${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
-IUSE="debug selinux test unwind"
-
-RDEPEND="virtual/libelf:=
-	selinux? ( sys-libs/libselinux )
-	unwind? ( sys-libs/libunwind:= )"
-DEPEND="${RDEPEND}
-	sys-libs/binutils-libs
-	test? ( dev-util/dejagnu )"
-
-# Effectively abandoned upstream. Extremely sensitive to the sandbox, versions
-# of core libraries, kernel security settings...
-RESTRICT="test"
-
-S=${WORKDIR}/${PN}-${EGIT_COMMIT}
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.7.91-debian-patchset-6.4.patch
-	"${FILESDIR}"/${PN}-0.7.3-CXX-for-tests.patch
-	"${FILESDIR}"/${PN}-0.7.3-alpha-protos.patch
-	"${FILESDIR}"/${PN}-0.7.3-ia64.patch
-	"${FILESDIR}"/${PN}-0.7.3-ia64-pid_t.patch
-	"${FILESDIR}"/${PN}-0.7.3-musl-host.patch
-	"${FILESDIR}"/${PN}-0.7.3-print-test-pie.patch
-	"${FILESDIR}"/${PN}-0.7.91-pid_t.patch
-	"${FILESDIR}"/${PN}-0.7.91-test-glibc-2.33.patch
-	"${FILESDIR}"/${PN}-0.7.91-tuple-tests.patch
-)
-
-src_prepare() {
-	default
-
-	sed -i '/^dist_doc_DATA/d' Makefile.am || die
-	eautoreconf
-}
-
-src_configure() {
-	ac_cv_header_selinux_selinux_h=$(usex selinux) \
-	ac_cv_lib_selinux_security_get_boolean_active=$(usex selinux) \
-	econf \
-		--disable-werror \
-		$(use_enable debug) \
-		$(use_with unwind libunwind)
-}
diff --git a/dev-util/ltrace/metadata.xml b/dev-util/ltrace/metadata.xml
index ca7a79566dae..7aee59bc9ad7 100644
--- a/dev-util/ltrace/metadata.xml
+++ b/dev-util/ltrace/metadata.xml
@@ -9,6 +9,7 @@
 		<remote-id type="gitlab">cespedes/ltrace</remote-id>
 	</upstream>
 	<use>
+		<flag name="elfutils">Use libdwfl from <pkg>sys-libs/libunwind</pkg> for frame unwinding support</flag>
 		<flag name="unwind">Use <pkg>sys-libs/libunwind</pkg> for frame unwinding support</flag>
 	</use>
 </pkgmetadata>
-- 
cgit v1.2.3-65-gdbad