net-misc/connman is not ready to go to stable, drop RDEPEND from stable candidate, -r1 for testing still has connman support.

Package-Manager: portage-2.1.9.36/cvs/Linux x86_64

4 files changed, 199 insertions, 14 deletions

diff --git a/mail-client/evolution/ChangeLog b/mail-client/evolution/ChangeLog
index 16aaba598b49..f8633f5c27f2 100644
--- a/mail-client/evolution/ChangeLog
+++ b/mail-client/evolution/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for mail-client/evolution
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.324 2011/02/07 11:32:40 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.325 2011/02/08 17:12:54 pacho Exp $
+
+*evolution-2.32.2-r1 (08 Feb 2011)
+
+  08 Feb 2011; Pacho Ramos <pacho@gentoo.org> evolution-2.32.2.ebuild,
+  +evolution-2.32.2-r1.ebuild:
+  net-misc/connman is not ready to go to stable, drop RDEPEND from stable
+  candidate, -r1 for testing still has connman support.
 
 *evolution-2.32.2 (07 Feb 2011)
 
diff --git a/mail-client/evolution/Manifest b/mail-client/evolution/Manifest
index 0efb51ebc260..d200428ba171 100644
--- a/mail-client/evolution/Manifest
+++ b/mail-client/evolution/Manifest
@@ -14,13 +14,14 @@ DIST evolution-2.32.2.tar.bz2 31929154 RMD160 1d68825111309600093c8d4718e1cc0016
 EBUILD evolution-2.30.2-r1.ebuild 4671 RMD160 dcaa724acda90a3921673541e3940e0fa021b34e SHA1 a8a79c08c2a13f7b535ad19e7ae4f6d5bb923bb2 SHA256 8c526518e7fcc12f12b24ffc9592c3577d265c88777ff45ac5bf9c6cc2665f1c
 EBUILD evolution-2.30.3.ebuild 4948 RMD160 128e174928216956da851ae76725373ee5625471 SHA1 41260cca5e4f960ec2a2dd9994e201ff8438f1bc SHA256 4b62d4fd7a3f2c4784247c30e914d4e4dd305354883d2df7bfa85b7bccfbf220
 EBUILD evolution-2.32.1-r1.ebuild 5620 RMD160 5ea41aba0a953fe49de0a69117522c6615141f71 SHA1 ec0a83b8156d329b0a735cc236440f16d8c09542 SHA256 0163b411327df97fb610f02762b9cded36c357ca719e57621701e651ae13b21e
-EBUILD evolution-2.32.2.ebuild 5459 RMD160 6bd306a675bf496e8716ea7fbc9c3418b87f018b SHA1 e0d9b9fe6b7d1b4b608bd709239d54592a558661 SHA256 37a1ee49817a717fb3c27f5e21fd187cb0c681a4d2900aea26776dee19ede1bd
-MISC ChangeLog 75249 RMD160 20b8f28b6d25440e327d32287909aa9230b838cb SHA1 99909f594da2d8b207cdc72faa9b6d47e9f5a8a4 SHA256 0591836195792f79468bbd6ad14ad50cb1b5dba70dbb3e9eb767761a62576f4d
+EBUILD evolution-2.32.2-r1.ebuild 5462 RMD160 cfdd64c48e8dcd2c952e080fbdbeec96b368199d SHA1 c0716ea619f959ba880ebb6c1088fa54e6421629 SHA256 5959bc4764d3ba3bac364b985c30e28790a487d1a37b3880e0084a954aa3069c
+EBUILD evolution-2.32.2.ebuild 5506 RMD160 36d89c1d3018e22c261cbba16e0b2f0183ac8ff1 SHA1 56d0a14ff249cf7ed77db263df49539d350269b1 SHA256 e7108a2b4baa4a949094c2e12c3b44ca0925c0106eb6f2891fca60097c736a21
+MISC ChangeLog 75518 RMD160 ed405ef365e707d7a06ebd4c23a9834f6ecff318 SHA1 86a74ad5fed16f6152fe4aea0631c9042eada82a SHA256 89a8f58727f31b3564d68c53a95c84cf9a585763ed4cc707de2dc03b0c4b1ce6
 MISC metadata.xml 1123 RMD160 abcc4bc1f7bbc92df0e35db1b59056fe5a4d05d2 SHA1 ecc4a4f56aeb9b5d0d9ec612308d9cb1ef9f9f3d SHA256 b188965e8c8ce0823c081f8b86653e3848665eb4b0d59fee4176589b549c6911
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.16 (GNU/Linux)
 
-iEYEARECAAYFAk1P2F8ACgkQCaWpQKGI+9T5OgCghKmf4oeFfCBnZL/89YYA/QlR
-bokAn0GuPqrtaRwbiHF+gUqiDIWTFr7P
-=ErYy
+iEYEARECAAYFAk1ReZwACgkQCaWpQKGI+9RqcACfYXByTK46s/OhdnA7cQToI/h0
+NK0An19oyhLtbnBWkWVeJHIquU6Mb970
+=9dlH
 -----END PGP SIGNATURE-----
diff --git a/mail-client/evolution/evolution-2.32.2-r1.ebuild b/mail-client/evolution/evolution-2.32.2-r1.ebuild
new file mode 100644
index 000000000000..8af399f705ff
--- /dev/null
+++ b/mail-client/evolution/evolution-2.32.2-r1.ebuild
@@ -0,0 +1,175 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.32.2-r1.ebuild,v 1.1 2011/02/08 17:12:54 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+PYTHON_DEPEND="python? 2:2.4"
+
+inherit autotools flag-o-matic gnome2 python versionator
+
+MY_MAJORV=$(get_version_component_range 1-2)
+
+DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
+HOMEPAGE="http://www.gnome.org/projects/evolution/"
+
+LICENSE="GPL-2 LGPL-2 OPENLDAP"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="clutter connman crypt doc gstreamer kerberos ldap networkmanager python ssl"
+
+# We need a graphical pinentry frontend to be able to ask for the GPG
+# password from inside evolution, bug 160302
+PINENTRY_DEPEND="|| ( app-crypt/pinentry[gtk] app-crypt/pinentry-qt app-crypt/pinentry[qt4] )"
+
+# contacts-map plugin requires libchaimplain and geoclue
+# glade-3 support is for maintainers only per configure.ac
+# mono plugin disabled as it's incompatible with 2.8 and lacks maintainance (see bgo#634571)
+# pst is not mature enough and changes API/ABI frequently
+RDEPEND=">=dev-libs/glib-2.25.12:2
+	>=x11-libs/gtk+-2.20.0:2
+	>=dev-libs/libunique-1.1.2
+	>=gnome-base/gnome-desktop-2.26:2
+	>=dev-libs/libgweather-2.25.3:2
+	media-libs/libcanberra[gtk]
+	>=x11-libs/libnotify-0.3
+	>=gnome-extra/evolution-data-server-${PV}[weather]
+	>=gnome-extra/gtkhtml-3.31.90:3.14
+	>=gnome-base/gconf-2
+	dev-libs/atk
+	>=dev-libs/libxml2-2.7.3
+	>=net-libs/libsoup-2.4:2.4
+	>=media-gfx/gtkimageview-1.6
+	>=x11-misc/shared-mime-info-0.22
+	>=x11-themes/gnome-icon-theme-2.30.2.1
+	>=dev-libs/libgdata-0.4
+
+	clutter? ( media-libs/clutter:1.0[gtk] )
+	connman? ( net-misc/connman )
+	crypt? ( || (
+				  ( >=app-crypt/gnupg-2.0.1-r2
+					${PINENTRY_DEPEND} )
+				  =app-crypt/gnupg-1.4* ) )
+	gstreamer? (
+		>=media-libs/gstreamer-0.10
+		>=media-libs/gst-plugins-base-0.10 )
+	kerberos? ( virtual/krb5 )
+	ldap? ( >=net-nds/openldap-2 )
+	networkmanager? ( >=net-misc/networkmanager-0.7 )
+	ssl? (
+		>=dev-libs/nspr-4.6.1
+		>=dev-libs/nss-3.11 )
+
+	!<gnome-extra/evolution-exchange-2.32"
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.16
+	>=dev-util/intltool-0.35.5
+	sys-devel/gettext
+	sys-devel/bison
+	app-text/scrollkeeper
+	>=app-text/gnome-doc-utils-0.9.1
+	app-text/docbook-xml-dtd:4.1.2
+	>=gnome-base/gnome-common-2.12
+	>=dev-util/gtk-doc-am-1.9
+	doc? ( >=dev-util/gtk-doc-1.9 )"
+# eautoreconf needs:
+#	>=gnome-base/gnome-common-2.12
+#	>=dev-util/gtk-doc-am-1.9
+
+pkg_setup() {
+	ELTCONF="--reverse-deps"
+	DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS* README"
+	G2CONF="${G2CONF}
+		--without-kde-applnk-path
+		--enable-plugins=experimental
+		--enable-image-inline
+		--enable-canberra
+		--enable-weather
+		$(use_enable ssl nss)
+		$(use_enable ssl smime)
+		$(use_enable networkmanager nm)
+		$(use_enable connman)
+		$(use_enable gstreamer audio-inline)
+		--disable-profiling
+		--disable-pst-import
+		$(use_enable python)
+		$(use_with clutter)
+		$(use_with ldap openldap)
+		$(use_with kerberos krb5 /usr)
+		--disable-contacts-map
+		--without-glade-catalog
+		--disable-mono
+		--disable-gtk3"
+
+	# dang - I've changed this to do --enable-plugins=experimental.  This will
+	# autodetect new-mail-notify and exchange, but that cannot be helped for the
+	# moment.  They should be changed to depend on a --enable-<foo> like mono
+	# is.  This cleans up a ton of crap from this ebuild.
+
+	# Use NSS/NSPR only if 'ssl' is enabled.
+	if use ssl ; then
+		G2CONF="${G2CONF} --enable-nss=yes"
+	else
+		G2CONF="${G2CONF}
+			--without-nspr-libs
+			--without-nspr-includes
+			--without-nss-libs
+			--without-nss-includes"
+	fi
+
+	# NM and connman support cannot coexist
+	if use networkmanager && use connman ; then
+		ewarn "It is not possible to enable both ConnMan and NetworkManager, disabling connman..."
+		G2CONF="${G2CONF} --disable-connman"
+	fi
+
+	python_set_active_version 2
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	epatch "${FILESDIR}"/${PN}-2.32.1-libnotify-0.7.patch
+
+	# Fix invalid use of la file in contact-editor, upstream bug #635002
+	epatch "${FILESDIR}/${PN}-2.32.0-wrong-lafile-usage.patch"
+
+	# Use NSS/NSPR only if 'ssl' is enabled.
+	if use ssl ; then
+		sed -e 's|mozilla-nss|nss|' \
+			-e 's|mozilla-nspr|nspr|' \
+			-i configure.ac configure || die "sed 2 failed"
+	fi
+
+	# Fix compilation flags crazyness
+	sed -e 's/CFLAGS="$CFLAGS $WARNING_FLAGS"//' \
+		-i configure.ac configure || die "sed 1 failed"
+
+	intltoolize --force --copy --automake || die "intltoolize failed"
+	eautoreconf
+}
+
+src_install() {
+	gnome2_src_install
+
+	find "${ED}"/usr/$(get_libdir)/evolution/${MY_MAJORV}/plugins \
+		-name "*.la" -delete || die "la files removal failed 1"
+	find "${ED}"/usr/$(get_libdir)/evolution/${MY_MAJORV}/modules \
+		-name "*.la" -delete || die "la files removal failed 2"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "To change the default browser if you are not using GNOME, do:"
+	elog "gconftool-2 --set /desktop/gnome/url-handlers/http/command -t string 'firefox %s'"
+	elog "gconftool-2 --set /desktop/gnome/url-handlers/https/command -t string 'firefox %s'"
+	elog ""
+	elog "Replace 'firefox %s' with which ever browser you use."
+	elog ""
+	elog "Junk filters are now a run-time choice. You will get a choice of"
+	elog "bogofilter or spamassassin based on which you have installed"
+	elog ""
+	elog "You have to install one of these for the spam filtering to actually work"
+}
diff --git a/mail-client/evolution/evolution-2.32.2.ebuild b/mail-client/evolution/evolution-2.32.2.ebuild
index 5edadfe827ac..6ffb4657af5f 100644
--- a/mail-client/evolution/evolution-2.32.2.ebuild
+++ b/mail-client/evolution/evolution-2.32.2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.32.2.ebuild,v 1.1 2011/02/07 11:32:40 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.32.2.ebuild,v 1.2 2011/02/08 17:12:54 pacho Exp $
 
 EAPI="3"
 GCONF_DEBUG="no"
@@ -16,7 +16,9 @@ HOMEPAGE="http://www.gnome.org/projects/evolution/"
 LICENSE="GPL-2 LGPL-2 OPENLDAP"
 SLOT="2.0"
 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="clutter connman crypt doc gstreamer kerberos ldap networkmanager python ssl"
+
+# connman is not ready to be stabilized, bug #353440
+IUSE="clutter crypt doc gstreamer kerberos ldap networkmanager python ssl"
 
 # We need a graphical pinentry frontend to be able to ask for the GPG
 # password from inside evolution, bug 160302
@@ -45,7 +47,6 @@ RDEPEND=">=dev-libs/glib-2.25.12:2
 	>=dev-libs/libgdata-0.4
 
 	clutter? ( media-libs/clutter:1.0[gtk] )
-	connman? ( net-misc/connman )
 	crypt? ( || (
 				  ( >=app-crypt/gnupg-2.0.1-r2
 					${PINENTRY_DEPEND} )
@@ -61,6 +62,7 @@ RDEPEND=">=dev-libs/glib-2.25.12:2
 		>=dev-libs/nss-3.11 )
 
 	!<gnome-extra/evolution-exchange-2.32"
+# connman? ( net-misc/connman )
 
 DEPEND="${RDEPEND}
 	>=dev-util/pkgconfig-0.16
@@ -89,7 +91,7 @@ pkg_setup() {
 		$(use_enable ssl nss)
 		$(use_enable ssl smime)
 		$(use_enable networkmanager nm)
-		$(use_enable connman)
+		--disable-connman
 		$(use_enable gstreamer audio-inline)
 		--disable-profiling
 		--disable-pst-import
@@ -119,10 +121,10 @@ pkg_setup() {
 	fi
 
 	# NM and connman support cannot coexist
-	if use networkmanager && use connman ; then
-		ewarn "It is not possible to enable both ConnMan and NetworkManager, disabling connman..."
-		G2CONF="${G2CONF} --disable-connman"
-	fi
+#	if use networkmanager && use connman ; then
+#		ewarn "It is not possible to enable both ConnMan and NetworkManager, disabling connman..."
+#		G2CONF="${G2CONF} --disable-connman"
+#	fi
 
 	python_set_active_version 2
 }