# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/devede/devede-3.23.0.ebuild,v 1.1 2013/01/16 13:03:09 lu_zero Exp $

EAPI=4

PYTHON_DEPEND="2:2.7"

inherit multilib python

DESCRIPTION="Program to create video CDs and DVDs, suitable to be played in home DVD players."
HOMEPAGE="http://www.rastersoft.com/programas/devede.html"
SRC_URI="http://www.rastersoft.com/descargas/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="-mencoder"

RDEPEND="dev-python/dbus-python
	dev-python/pycairo
	dev-python/pygobject:2
	>=dev-python/pygtk-2.16
	media-video/dvdauthor
	mencoder? ( media-video/mplayer[mp3,encode] )
	media-video/vcdimager
	virtual/cdrtools
	!mencoder? ( virtual/ffmpeg[mp3,encode]
				|| ( media-video/mplayer2[symlink] media-video/mplayer ) )"
DEPEND=""

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	python_convert_shebangs -r 2 .
}

src_install() {
	./install.sh DESTDIR="${D}" libdir="/usr/$(get_libdir)" \
	pkgdocdir=/usr/share/doc/${PF} prefix=/usr || die
}

pkg_postinst() {
	python_mod_optimize /usr/$(get_libdir)/${PN}
	elog "To change the font used to render the subtitles, choose a TrueType font you like"
	elog "and copy it in \$HOME/.spumux directory, renaming it to devedesans.ttf."
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/${PN}
}