blob: 2628d75ce06917620c314ee6afaa6d20ade3d778 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/gnome-keyring-3.12.2-r1.ebuild,v 1.9 2014/10/11 12:00:19 maekke Exp $
EAPI="5"
GCONF_DEBUG="yes" # Not gnome macro but similar
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 )
inherit fcaps gnome2 pam python-any-r1 versionator virtualx
DESCRIPTION="Password and keyring managing daemon"
HOMEPAGE="https://wiki.gnome.org/Projects/GnomeKeyring"
LICENSE="GPL-2+ LGPL-2+"
SLOT="0"
IUSE="+caps debug pam selinux +ssh-agent"
KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
RDEPEND="
>=app-crypt/gcr-3.5.3:=[gtk]
>=dev-libs/glib-2.38:2
app-misc/ca-certificates
>=dev-libs/libgcrypt-1.2.2:0=
>=sys-apps/dbus-1.1.1
caps? ( sys-libs/libcap-ng )
pam? ( virtual/pam )
"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
app-text/docbook-xml-dtd:4.3
dev-libs/libxslt
>=dev-util/intltool-0.35
sys-devel/gettext
virtual/pkgconfig
"
pkg_setup() {
python-any-r1_pkg_setup
}
src_prepare() {
# Disable stupid CFLAGS
sed -e 's/CFLAGS="$CFLAGS -g"//' \
-e 's/CFLAGS="$CFLAGS -O0"//' \
-i configure.ac configure || die
# FIXME: some tests write to /tmp (instead of TMPDIR)
# Disable failing tests
sed -e 's|\(g_test_add.*/gkm/data-asn1/integers.*;\)|/*\1*/|' \
-i "${S}"/pkcs11/gkm/test-data-asn1.c || die
sed -e 's|\(g_test_add.*/gkm/timer/cancel.*;\)|/*\1*/|' \
-i "${S}"/pkcs11/gkm/test-timer.c || die
# For some reason all pam tests make the testsuite retun 77
# which is considered an error but the test framework,
# but all tests are successful, upstream bug #731030
sed -e '558,595 d' -i "${S}"/pam/test-pam.c || die
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
$(use_with caps libcap-ng) \
$(use_enable pam) \
$(use_with pam pam-dir $(getpam_mod_dir)) \
$(use_enable selinux) \
$(use_enable ssh-agent) \
--enable-doc \
--enable-gpg-agent
}
src_test() {
# FIXME: this should be handled at eclass level
"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/schema" || die
unset DBUS_SESSION_BUS_ADDRESS
GSETTINGS_SCHEMA_DIR="${S}/schema" Xemake check
}
pkg_postinst() {
# cap_ipc_lock only needed if building --with-libcap-ng
# Never install as suid root, this breaks dbus activation, see bug #513870
use caps && fcaps -m 755 cap_ipc_lock usr/bin/gnome-keyring-daemon
gnome2_pkg_postinst
}
|
GitWeb