3 files changed, 79 insertions, 0 deletions
diff --git a/sys-power/gwe/Manifest b/sys-power/gwe/Manifest
new file mode 100644
index 000000000..4b1465161
--- /dev/null
+++ b/sys-power/gwe/Manifest
@@ -0,0 +1 @@
+DIST gwe-0.15.2.tar.gz 365396 BLAKE2B 166afc622c13829f727304f9d5ba0a39a0c6f8225222f26e342b3791ed9e2d45c2bb996129cc09b88b6a1ee4effe51a160825fa70a92d1e6ae5458d0eaf431d8 SHA512 f6e0e0cb6e5139fd81371fc3e6eb50d2f87193608de4db99d87891da3ecc90828a80e8a7d0c653ea781bee9ced14353e73d0362e92d1c2b4e29b6c3df2d46a57
diff --git a/sys-power/gwe/gwe-0.15.2.ebuild b/sys-power/gwe/gwe-0.15.2.ebuild
new file mode 100644
index 000000000..13f2933e0
--- /dev/null
+++ b/sys-power/gwe/gwe-0.15.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit gnome2-utils meson python-single-r1 xdg-utils
+
+DESCRIPTION="NVIDIA settings alternative with overclocking, fan control, and information"
+HOMEPAGE="https://gitlab.com/leinardi/gwe"
+SRC_URI="https://gitlab.com/leinardi/gwe/-/archive/${PV}/${P}.tar.gz"
+
+KEYWORDS="~amd64"
+SLOT="0"
+LICENSE="GPL-3"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+		${PYTHON_DEPS}
+		dev-libs/gobject-introspection
+		dev-libs/libappindicator:3
+		dev-libs/libdazzle
+
+		$(python_gen_cond_dep '
+			dev-python/injector[${PYTHON_USEDEP}]
+			dev-python/matplotlib[${PYTHON_USEDEP}]
+			dev-python/peewee[${PYTHON_USEDEP}]
+			dev-python/py3nvml[${PYTHON_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			dev-python/python-xlib[${PYTHON_USEDEP}]
+			dev-python/pyxdg[${PYTHON_USEDEP}]
+			dev-python/requests[${PYTHON_USEDEP}]
+			dev-python/Rx[${PYTHON_USEDEP}]
+		')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+		${RDEPEND}
+		dev-libs/appstream-glib
+		virtual/pkgconfig
+"
+
+src_prepare() {
+	# Disable post-inst script – let the ebuild handle it
+	sed -i meson.build \
+		-e "s:meson.add_install_script('scripts/meson_post_install.py')::g" \
+		|| die
+
+	default
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/sys-power/gwe/metadata.xml b/sys-power/gwe/metadata.xml
new file mode 100644
index 000000000..6535f7da7
--- /dev/null
+++ b/sys-power/gwe/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>octiabrina@myrvogna.net</email>
+		<name>Octiabrina Terrien-Puig</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="gitlab">leinardi/gwe</remote-id>
+	</upstream>
+</pkgmetadata>