dev-python/plotly: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 107 deletions

diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index f5b5870ba58b..b85dd268eefd 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1,2 +1 @@
-DIST plotly.py-5.14.1.gh.tar.gz 30697895 BLAKE2B 2fd602b353cf6097f3b0341cdd07b82fe38181a2c2cf21a7a7fe3b88c65160ac0b1a000bad9eca540754570f0b06b746f286f2a7bc89dfdd4454356165b6ded9 SHA512 cf053ea47425ad4f4f1412ce8ba037f49609a292b61afaa63bd8c00f010353f56a648cded408b9788055e2bba69e6a71192b55602d11d4122dc76e6dd3085a11
 DIST plotly.py-5.15.0.gh.tar.gz 30801940 BLAKE2B bb95df7402a308c1a32817dc12d519a446f63cfe34f6a6c492949465734132a2d86078849790ee51d6cb99fbaf434251c48204e0b2b36af422fdf7efbc446a6a SHA512 418f05fd6eb17de3619c647ba83817144d8b9f7eec766cae492fb9987ad1e5ff169cfe045d163997916bdf0df75dafba94fb55c68a5dfb45c8aa87cb3e0e4658
diff --git a/dev-python/plotly/plotly-5.14.1.ebuild b/dev-python/plotly/plotly-5.14.1.ebuild
deleted file mode 100644
index 760cd2ec5a69..000000000000
--- a/dev-python/plotly/plotly-5.14.1.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..11} )
-DISTUTILS_USE_PEP517=setuptools
-
-inherit distutils-r1
-
-MY_P=plotly.py-${PV}
-DESCRIPTION="Browser-based graphing library for Python"
-HOMEPAGE="
-	https://plotly.com/python/
-	https://github.com/plotly/plotly.py/
-	https://pypi.org/project/plotly/
-"
-SRC_URI="
-	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S="${WORKDIR}/${MY_P}/packages/python/plotly"
-# The tests are not included in the PyPI tarball, to use the GitHub tarball
-# we have to skip npm, which means that the resulting install will
-# unfortunately lack the jupyterlab extension.
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/packaging[${PYTHON_USEDEP}]
-	>=dev-python/tenacity-6.2.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/ipykernel[${PYTHON_USEDEP}]
-		dev-python/ipython[${PYTHON_USEDEP}]
-		dev-python/ipywidgets[${PYTHON_USEDEP}]
-		dev-python/jupyter[${PYTHON_USEDEP}]
-		dev-python/jupyterlab[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/pandas[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/pytz[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		dev-python/shapely[${PYTHON_USEDEP}]
-		dev-python/statsmodels[${PYTHON_USEDEP}]
-		dev-python/xarray[${PYTHON_USEDEP}]
-		sci-libs/scikit-image[${PYTHON_USEDEP}]
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-5.8.0-fix-versioneer-import.patch
-)
-
-EPYTEST_IGNORE=(
-	# Needs porting to newer numpy
-	_plotly_utils/tests/validators/test_integer_validator.py
-
-	# kaleido not packaged
-	plotly/tests/test_optional/test_kaleido
-
-	# plotly-orca not packaged
-	plotly/tests/test_orca
-)
-
-EPYTEST_DESELECT=(
-	# Also needs porting to newer numpy
-	plotly/tests/test_io/test_to_from_plotly_json.py::test_object_numpy_encoding
-
-	# kaleido not packaged
-	plotly/tests/test_orca/test_to_image.py::test_bytesio
-
-	# Fails if not already installed
-	test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
-	test_init/test_lazy_imports.py::test_lazy_imports
-
-	# Minor matplotlib incompatibility
-	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_path_collection
-	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
-	plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
-
-	# In python 3.11 the produced error is slightly different
-	plotly/tests/test_core/test_errors/test_dict_path_errors.py::test_described_subscript_error_on_type_error
-)
-
-# There are sphinx docs but we are missing a bunch of dependencies.
-# distutils_enable_sphinx ../../../doc/apidoc
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# Do not try to fetch stuff with npm
-	export SKIP_NPM=1
-	distutils-r1_python_prepare_all
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	mv "${ED}"/{usr/etc,etc} || die
-}