dev-ruby/yajl-ruby: add 1.3.1, fixing bug 636474

Bug: https://bugs.gentoo.org/636474
Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-ruby/yajl-ruby/yajl-ruby-1.3.1.ebuild b/dev-ruby/yajl-ruby/yajl-ruby-1.3.1.ebuild
new file mode 100644
index 000000000000..b8ecc24eded6
--- /dev/null
+++ b/dev-ruby/yajl-ruby/yajl-ruby-1.3.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_TASK_DOC=""
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Ruby C bindings to the Yajl JSON stream-based parser library"
+HOMEPAGE="https://github.com/brianmario/yajl-ruby"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="${RDEPEND} dev-libs/yajl"
+DEPEND="${DEPEND} dev-libs/yajl"
+
+each_ruby_prepare() {
+	# Make sure the right ruby interpreter is used
+	sed -e '/capture/ s:ruby:'${RUBY}':' -i spec/parsing/large_number_spec.rb || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/yajl extconf.rb || die "extconf.rb failed"
+}
+
+each_ruby_compile() {
+	emake -Cext/yajl CFLAGS="${CFLAGS} -fPIC" archflag="${LDFLAGS}" V=1
+	cp ext/yajl/yajl$(get_modname) lib/yajl/ || die
+}
+
+each_ruby_test() {
+	# Set RUBYLIB to pass search path on to additional interpreters that
+	# are started.
+	RUBYLIB=lib ruby-ng_rspec || die
+}