dev-util/pwntools: add 4.11.1

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-util/pwntools/Manifest b/dev-util/pwntools/Manifest
index c91044e47120..d034d4cc766a 100644
--- a/dev-util/pwntools/Manifest
+++ b/dev-util/pwntools/Manifest
@@ -1,2 +1,3 @@
 DIST pwntools-4.11.0.gh.tar.gz 4237576 BLAKE2B 11b1b6a923c44ee1b5027b4a71f9f3b6b9bcd36a2a38915ee46ffc855b0749528a204581dcb5071d50031701924b3cc08edf95b363d1d1b6e76d029a91011293 SHA512 a5be69a19cea933680f1946e389fad4edbbdb0d6106cd1f78778f901a6ddaaef734389678c5b4f16718a788d53bff6025817d83c06ab3dc1a200a5ff3c696aaa
+DIST pwntools-4.11.1.gh.tar.gz 4237695 BLAKE2B 10a0b363d7255e856a33ce972a9eab2ec51d1d5f6ee953ac37796f87cf42b46b1207dc31f64902af704b7f36125c765e0c9328d44c6b0dda34a133238b42cf7f SHA512 f3c9d35ea62215a05a97ca00d908f3aea2188b9b2cbb8baac6b4203ac699e82f3d13b1332007e3b5d46973d609271fdd5e2dbd3aa70f7735f5578a449ca90fe6
 DIST pwntools-4.12.0_beta0.gh.tar.gz 4244487 BLAKE2B a5312c5c454ddfbdbfd27ddf200194155db1dbc6bd545bc2de0ba0d18bee731dc9d7109e205e4426776a12a9cf715a45a365afd1b624edd0d3e1abb81e3a1936 SHA512 d14ea4283b78387362673c5416e2c7aa55c6ac5e2cd7191f57b28afdf55b1cf8c4044c265022591f30f56bcf7bde8d745e2dc70ada6763abf07c43899516f537
diff --git a/dev-util/pwntools/pwntools-4.11.1.ebuild b/dev-util/pwntools/pwntools-4.11.1.ebuild
new file mode 100644
index 000000000000..7811e0a1eebf
--- /dev/null
+++ b/dev-util/pwntools/pwntools-4.11.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="CTF framework and exploit development library"
+HOMEPAGE="https://github.com/Gallopsled/pwntools"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Gallopsled/pwntools.git"
+else
+	SRC_URI="https://github.com/Gallopsled/pwntools/archive/${PV/_beta/beta}.tar.gz -> ${P}.gh.tar.gz"
+	if [[ ${PV} != *_beta* ]] ; then
+		KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+	fi
+	S="${WORKDIR}/${PN}-${PV/_beta/beta}"
+fi
+
+LICENSE="MIT GPL-2+ BSD-2"
+SLOT="0"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/capstone-3.0.5[python,${PYTHON_USEDEP}]
+	>=dev-util/ROPgadget-5.3[${PYTHON_USEDEP}]
+	>=dev-util/unicorn-1.0.2[python,${PYTHON_USEDEP}]
+	dev-python/colored-traceback[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-1.15.2[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyelftools-0.24[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyserial-2.7[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0[${PYTHON_USEDEP}]
+	dev-python/rpyc[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.11.0_update_deps.patch"
+)
+
+python_configure_all() {
+	DISTUTILS_ARGS=(
+		--only-use-pwn-command
+	)
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp extra/bash_completion.d/pwn pwn
+	newbashcomp extra/bash_completion.d/shellcraft shellcraft
+
+	insinto /usr/share/zsh/site-functions
+	doins extra/zsh_completion/_pwn
+
+	# Disable automatic update check (bug 915496).
+	insinto /etc
+	doins "${FILESDIR}/pwn.conf"
+
+	rm -r "${ED}/usr/pwntools-doc" || die
+}