mail-client/mutt-2.0.4-r1: revbump with patch for #765790

Bug: https://bugs.gentoo.org/765790
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Fabian Groffen <grobian@gentoo.org>

3 files changed, 2 insertions, 269 deletions

diff --git a/mail-client/mutt/Manifest b/mail-client/mutt/Manifest
index e802d07e53ca..a59f7d021e99 100644
--- a/mail-client/mutt/Manifest
+++ b/mail-client/mutt/Manifest
@@ -1,6 +1,4 @@
 DIST mutt-2.0.2.tar.gz 5293613 BLAKE2B 215a4d54e6dd202ebced91d0536a7f70e774b3c41c129ef87a55ea75a298e485b72145e5dd3c654d9b28138800c4b3e87a3815ab789d952b6b58cfc068fd397b SHA512 5dea02edf60b33e4873806481aa4256f91d90b05de99a9eccc620c459bd924197b656f85eb5a31757a61675389e6c4d76571128a757cfda255240934e82eec29
-DIST mutt-2.0.3.tar.gz 5292808 BLAKE2B 323a63b1b4ece774674b6f207ae51ffb58e57fd90fa2a44d8a69bb5311bf66318f8d6e8ca20b333bb7e3bea1ef995ab84f1f6cd8486ee91fbfdb90e2d64444b9 SHA512 6511f6690137f2cd8798a6c76a6f1a6305b2ddaad9bf339ec7144f6c249fe9cbcfb5bfbbdd308fcc6829b7fa12132b14d555dd3a9ef9e9b46c9748e2f31be852
 DIST mutt-2.0.4.tar.gz 5293913 BLAKE2B 9c5d2d17fae9653868cca08eb7d92f9c6e122702590ba88a2ba04ee8606cfba5bca99716045b59cf40a21e95a0e32f3b21a34ee34440f155a3e2788720c3d57c SHA512 8080107810d2ff572b1532bb441573e4dcfbfbc03f28be711dcdebd1e6a1c8b5adf5c5a4f386ce0a661ff7050722b41e122c58964feae665ff4138013af18762
 DIST mutt-gentoo-2.0.2-patches-r0.tar.xz 26380 BLAKE2B 3ce2dbe07f9340adbaeb0489fe88564b6cc44ef330d298915d42617357799a26f277cc0dcab2b78a5620f20a2533f2fe43287bab76eeb9529013e9f9c7659ffb SHA512 79fb00ccf6084da805c75eedbdb1631b12e616318e91a4c246d0194a478b803e3dc5d2815f757fecc91316c010058c2d0e9ecaf3fe40d5664ac25af63a0d7e13
-DIST mutt-gentoo-2.0.3-patches-r0.tar.xz 26396 BLAKE2B 1ee41baedb2ade72437ec4ffbd617e7e8a07c432ae2c025001df7fc19b2e6181e54f25dd16f02027f03f0f9df0032b35088354ae8c2c238a57fea2c3407dee4e SHA512 290416aa72d6938c9f52f60702ae1a9306704a3c63ca35c8fb35902c8e2307da42b478718521ebe0d6b857089b778bc172cd9cf5f061fab56fe5dea47c01f792
-DIST mutt-gentoo-2.0.4-patches-r0.tar.xz 26448 BLAKE2B 7f2e2730e18def7281cf59bc783ebc4047e459ebb8796810507ff11f5e99b78c2d6914be154251f1a279b4963156825931e22cd727e86eb40c15637736be457e SHA512 16025a790fba20ba1e693b1b826bf86bd2697d0d3ab5ceaf08b1692902235ef40866daec80862c7082a82a58fa4f9631889688f1d06b864cb29c613725fe5024
+DIST mutt-gentoo-2.0.4-patches-r1.tar.xz 26908 BLAKE2B b2ca74496328cd9bcc0eb843e48b99a6a066be6530228534d2d0a60223984e03dde2718116d8314f9cec0f22db0c4fa52521ed4fb95f7e153cfc7fb9f37f84a8 SHA512 7bb6617d900d1058e1d6b9fefd1d557efc669386501c281976c93c2a4c0d1a1a1de459dd39c46a257bd3f9bd64155e1c92add1421d40ed4e061f2fc26d17600a
diff --git a/mail-client/mutt/mutt-2.0.3.ebuild b/mail-client/mutt/mutt-2.0.4-r1.ebuild
index c9a2e340a3c6..5131f8871a13 100644
--- a/mail-client/mutt/mutt-2.0.3.ebuild
+++ b/mail-client/mutt/mutt-2.0.4-r1.ebuild
@@ -5,7 +5,7 @@ EAPI="6"
 
 inherit eutils flag-o-matic autotools
 
-PATCHREV="r0"
+PATCHREV="r1"
 PATCHSET="gentoo-${PVR}/${PATCHREV}"
 
 DESCRIPTION="A small but very powerful text-based mail client"
diff --git a/mail-client/mutt/mutt-2.0.4.ebuild b/mail-client/mutt/mutt-2.0.4.ebuild
deleted file mode 100644
index c9a2e340a3c6..000000000000
--- a/mail-client/mutt/mutt-2.0.4.ebuild
+++ /dev/null
@@ -1,265 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-
-inherit eutils flag-o-matic autotools
-
-PATCHREV="r0"
-PATCHSET="gentoo-${PVR}/${PATCHREV}"
-
-DESCRIPTION="A small but very powerful text-based mail client"
-HOMEPAGE="http://www.mutt.org/"
-MUTT_G_PATCHES="mutt-gentoo-${PV}-patches-${PATCHREV}.tar.xz"
-SRC_URI="ftp://ftp.mutt.org/pub/mutt/${P}.tar.gz
-	https://bitbucket.org/${PN}/${PN}/downloads/${P}.tar.gz
-	https://dev.gentoo.org/~grobian/distfiles/${MUTT_G_PATCHES}"
-IUSE="autocrypt berkdb debug doc gdbm gnutls gpgme +hcache idn +imap kerberos libressl +lmdb mbox nls pgp-classic pop qdbm +sasl selinux slang smime-classic +smtp +ssl tokyocabinet vanilla prefix"
-# hcache: allow multiple, bug #607360
-REQUIRED_USE="
-	hcache?           ( || ( berkdb gdbm lmdb qdbm tokyocabinet ) )
-	imap?             ( ssl )
-	pop?              ( ssl )
-	smime-classic?    ( ssl !gnutls )
-	smtp?             ( ssl sasl )
-	sasl?             ( || ( imap pop smtp ) )
-	kerberos?         ( || ( imap pop smtp ) )
-	autocrypt?        ( gpgme )"
-SLOT="0"
-LICENSE="GPL-2"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-# yes, we overdepend on the backend impls here, hopefully one day we can
-# have REQUIRED_USE do what it is made for again. bug #607360
-CDEPEND="
-	app-misc/mime-types
-	virtual/libiconv
-
-	berkdb?        ( >=sys-libs/db-4:= )
-	gdbm?          ( sys-libs/gdbm )
-	lmdb?          ( dev-db/lmdb:= )
-	qdbm?          ( dev-db/qdbm )
-	tokyocabinet?  ( dev-db/tokyocabinet )
-
-	ssl? (
-		gnutls?    ( >=net-libs/gnutls-1.0.17:= )
-		!gnutls? (
-			libressl? ( dev-libs/libressl:= )
-			!libressl? ( >=dev-libs/openssl-0.9.6:0= )
-		)
-	)
-
-	nls?           ( virtual/libintl )
-	sasl?          ( >=dev-libs/cyrus-sasl-2 )
-	kerberos?      ( virtual/krb5 )
-	idn?           ( net-dns/libidn2 )
-	gpgme?         ( >=app-crypt/gpgme-0.9.0:= )
-	autocrypt?     ( >=dev-db/sqlite-3 )
-	slang?         ( sys-libs/slang )
-	!slang?        ( >=sys-libs/ncurses-5.2:0= )
-"
-DEPEND="${CDEPEND}
-	net-mail/mailbase
-	doc? (
-		dev-libs/libxml2
-		dev-libs/libxslt
-		app-text/docbook-xsl-stylesheets
-		|| ( www-client/lynx www-client/w3m www-client/elinks )
-	)"
-RDEPEND="${CDEPEND}
-	selinux? ( sec-policy/selinux-mutt )
-	smime-classic? ( || ( dev-libs/libressl >=dev-libs/openssl-0.9.6:0 ) )
-	pgp-classic? ( app-crypt/gnupg )
-"
-
-src_prepare() {
-	local PATCHDIR="${WORKDIR}"/mutt-gentoo-${PV}-patches-${PATCHREV}
-
-	if use !vanilla ; then
-		# apply patches
-		export EPATCH_FORCE="yes"
-		export EPATCH_SUFFIX="patch"
-		# http://hg.code.sf.net/p/gentoomuttpatches/code/file/mutt-1.10
-		local patches=(
-			patches-mutt
-			bugs-gentoo
-			features-common
-			features-extra
-			gentoo
-		)
-		local patchset
-		for patchset in "${patches[@]}" ; do
-			[[ -d "${PATCHDIR}/${patchset}" ]] || continue
-			einfo "Patches for ${PATCHSET} patchset ${patchset}"
-			EPATCH_SOURCE="${PATCHDIR}"/${patchset} epatch \
-				|| die "patchset ${patchset} failed"
-		done
-		# add some explanation as to why not to go upstream
-		sed -i \
-			-e '/ReachingUs = N_(/aThis release of Mutt is heavily enriched with patches.\\nFor this reason, any bugs are better reported at https://bugs.gentoo.org/\\nor re-emerge with USE=vanilla and try to reproduce your problem.\\n\\' \
-			main.c || die "Failed to add bug instructions"
-	fi
-
-	local upatches=
-	# allow user patches
-	eapply_user && upatches=" with user patches"
-
-	# patch version string for bug reports
-	local patchset=
-	use vanilla || patchset=", ${PATCHSET}"
-	sed -i -e 's|"Mutt %s (%s)"|"Mutt %s (%s'"${patchset}${upatches}"')"|' \
-		muttlib.c || die "failed patching in Gentoo version"
-
-	# many patches touch the buildsystem, we always need this
-	AT_M4DIR="m4" eautoreconf
-
-	# the configure script contains some "cleverness" whether or not to setgid
-	# the dotlock program, resulting in bugs like #278332
-	sed -i -e 's/@DOTLOCK_GROUP@//' Makefile.in || die "sed failed"
-}
-
-src_configure() {
-	local myconf=(
-		# signing and encryption
-		$(use_enable autocrypt) $(use_with autocrypt sqlite3)
-		$(use_enable pgp-classic pgp)
-		$(use_enable smime-classic smime)
-		$(use_enable gpgme)
-
-		# features
-		$(use_enable debug)
-		$(use_enable doc)
-		$(use_enable nls)
-
-		# protocols
-		$(use_enable imap)
-		$(use_enable pop)
-		$(use_enable smtp)
-
-		$(use  ssl && use  gnutls && echo --with-gnutls    --without-ssl)
-		$(use  ssl && use !gnutls && echo --without-gnutls --with-ssl   )
-		$(use !ssl &&                echo --without-gnutls --without-ssl)
-
-		$(use_with sasl)
-		$(use_with idn idn2) --without-idn  # avoid automagic libidn dep
-		$(use_with kerberos gss)
-		"$(use slang && echo --with-slang="${EPREFIX}"/usr || echo a=b)"
-		"$(use_with !slang curses "${EPREFIX}"/usr)"
-
-		"--enable-compressed"
-		"--enable-external-dotlock"
-		"--enable-iconv"
-		"--enable-nfs-fix"
-		"--enable-sidebar"
-		"--sysconfdir=${EPREFIX}/etc/${PN}"
-		"--with-docdir=${EPREFIX}/usr/share/doc/${PN}-${PVR}"
-		"--without-bundled-regex"     # use the implementation from libc
-		"--with-exec-shell=${EPREFIX}/bin/sh"
-	)
-
-	if [[ ${CHOST} == *-solaris2.* && ${CHOST#*-solaris2.} -le 10 ]] ; then
-		# arrows in index view do not show when using wchar_t
-		# or misalign due to wrong computations
-		myconf+=( "--without-wc-funcs" )
-	fi
-
-	# note: REQUIRED_USE should have selected only one of these, but for
-	# bug #607360 we're forced to allow multiple.  For that reason, this
-	# list is ordered to preference, and only the first is taken.
-	local hcaches=(
-		"lmdb"
-		"qdbm"
-		"tokyocabinet"
-		"gdbm"
-		"berkdb:bdb"
-	)
-	local ucache hcache lcache
-	for hcache in "${hcaches[@]}" ; do
-		if use ${hcache%%:*} ; then
-			ucache=${hcache}
-			break
-		fi
-	done
-	if [[ -n ${ucache} ]] ; then
-		myconf+=( "--enable-hcache" )
-	else
-		myconf+=( "--disable-hcache" )
-	fi
-	for hcache in "${hcaches[@]}" ; do
-		[[ ${hcache} == ${ucache} ]] \
-			&& myconf+=( "--with-${hcache#*:}" ) \
-			|| myconf+=( "--without-${hcache#*:}" )
-	done
-
-	if use mbox; then
-		myconf+=( "--with-mailpath=${EPREFIX}/var/spool/mail" )
-	else
-		myconf+=( "--with-homespool=Maildir" )
-	fi
-
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	emake DESTDIR="${D}" install
-	insinto /etc/${PN}
-	if use mbox; then
-		newins "${FILESDIR}"/Muttrc.mbox Muttrc
-	else
-		doins "${FILESDIR}"/Muttrc
-	fi
-
-	# include attachment settings, it's mandatory and shouldn't harm
-	# when not being referenced (index_format using %X)
-	{
-		echo
-		echo "# mandatory attachments settings, not setting these is a BUG!"
-		echo "# see https://marc.info/?l=mutt-dev&m=158347284923517&w=2"
-		grep '^attachments' "${ED}"/etc/${PN}/Muttrc.dist
-	} >> "${ED}"/etc/${PN}/Muttrc
-
-	# add setting to actually enable gpgme usage
-	if use gpgme || use autocrypt ; then
-		{
-		echo
-		echo "# this setting enables the gpgme backend (via USE=gpgme)"
-		# https is broken due to a certificate mismatch :(
-		echo "# see http://www.mutt.org/doc/manual/#crypt-use-gpgme"
-		echo "set crypt_use_gpgme = yes"
-		} >> "${ED}"/etc/${PN}/Muttrc
-	fi
-
-	# similar for autocrypt
-	if use autocrypt ; then
-		{
-			echo
-			echo "# enables autocrypt (via USE=autocrypt)"
-			echo "# see http://www.mutt.org/doc/manual/#autocryptdoc"
-			echo "set autocrypt = yes"
-		} >> "${ED}"/etc/${PN}/Muttrc
-	fi
-
-	# A newer file is provided by app-misc/mime-types. So we link it.
-	rm "${ED}"/etc/${PN}/mime.types
-	dosym ../mime.types /etc/${PN}/mime.types
-
-	# nuke manpages that should be provided by an MTA, bug #177605
-	rm "${ED}"/usr/share/man/man5/{mbox,mmdf}.5 \
-		|| ewarn "failed to remove files, please file a bug"
-
-	if use !prefix ; then
-		fowners root:mail /usr/bin/mutt_dotlock
-		fperms g+s /usr/bin/mutt_dotlock
-	fi
-
-	dodoc COPYRIGHT ChangeLog NEWS OPS* PATCHES README* TODO VERSION
-}
-
-pkg_postinst() {
-	if [[ -z ${REPLACING_VERSIONS} ]] ; then
-		echo
-		elog "If you are new to mutt you may want to take a look at"
-		elog "the Gentoo QuickStart Guide to Mutt E-Mail:"
-		elog "   https://wiki.gentoo.org/wiki/Mutt"
-		echo
-	fi
-}