net-misc/youtube-dl: Version 2020.02.16

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 096f4f985d40..eb90025c0a27 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2020.01.24.tar.gz 3159926 BLAKE2B 0b1be74f74eb0be6cb0a41faf0538110bfc5d1a213fa1c456a6a358096f16ac8768ebd3d4673e523251fd0721a4a0990f061713d32b13c11077e79f8f02989e1 SHA512 8f85a218395d2932b26c7b76d5b03cbdf9a7c541415c8d1b805239b6ab1ca74b94fc497f32052a1d93fe20ac760994975a13551dd8c5319f0549af20b70a1a78
+DIST youtube-dl-2020.02.16.tar.gz 3161956 BLAKE2B 36cd189b162d98f986d669c4439070efbf344aa05f821b9e35a58fcef8db839ad0e079836e7a84cd17b04afdb113559695ad500f4b0183c7dcefa1694bdccf62 SHA512 1164ad9f875d67844ddc7bf8214bcc06cb384d7f2a5661c1f419f2ce5950b1cfcbf90c558e143b76948d9d7cf57cf3843c8d6392fc6ef77f89319375610f01a2
diff --git a/net-misc/youtube-dl/youtube-dl-2020.02.16.ebuild b/net-misc/youtube-dl/youtube-dl-2020.02.16.ebuild
new file mode 100644
index 000000000000..cc4f38a726e5
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.02.16.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python3_{6,7,8})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}