net-misc/freerdp: bump to 2.1.2

Bug: https://bugs.gentoo.org/729218
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

2 files changed, 125 insertions, 0 deletions

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
index 513a5b7b975e..25a9796c59c9 100644
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -1,2 +1,3 @@
 DIST freerdp-2.1.0.tar.gz 6869116 BLAKE2B c9cab4b571b288450efa5c5666f8cb64ca9e37dfd342d5e66c256b0fca151b20b3f9b1027a12f8fe9cbae186d95c8cb4d28c90deeadcacc3c158f50a3e713747 SHA512 86d72419d012c52a3dfa071d50bac96ddb3a1423bf35252fdef72676f8b2830b65c9e0511dea2d7b9a69e7783a3d1eacbd2f868b08836742dec7542c77a39405
 DIST freerdp-2.1.1.tar.gz 6871637 BLAKE2B b0c01fb074f28aa569d934797d4fb8451edcb90d7f5eba9e47b7ec844cc95eda143c3d851b86ef72e233e8bde8ebc3e1c4a7d3d549d0de54f774ec1fee62e8cd SHA512 6f0cff79690ca550237c6e31f5ab361246a6d12ac765e85b752d474aceaf1390d8c5f2b21aba028927459892a045e5073e143705e6f2256a2a7c8744dcf3f95b
+DIST freerdp-2.1.2.tar.gz 6838848 BLAKE2B 2ca0e7f22311b574c09b3040a95133ad99ffa0cb91bc6992bf0fa88f8aebfccda3599f3d7f14a0813256c249c1e90fbd6e907fe36f78627fbd4ab6852353ea49 SHA512 09fbd76512661e077c4baab4056c2e636cfb0067678271c6c87dc19fb035e15a463478f697f7caedc0d650089d520f97f6143e85ef1b29f12c41cbd39b8fff92
diff --git a/net-misc/freerdp/freerdp-2.1.2.ebuild b/net-misc/freerdp/freerdp-2.1.2.ebuild
new file mode 100644
index 000000000000..0370121a8a94
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.1.2.ebuild
@@ -0,0 +1,124 @@
+# Copyright 2011-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+	case ${PV} in
+		2.*) EGIT_BRANCH="stable-2.0";;
+	esac
+else
+	MY_P=${P/_/-}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa cpu_flags_arm_neon cups debug doc +ffmpeg gstreamer jpeg libressl openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	usb? (
+		virtual/libudev:0=
+		sys-apps/util-linux:0=
+		dev-libs/dbus-glib:0=
+		virtual/libusb:1=
+	)
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		xinerama? ( x11-libs/libXinerama )
+		xv? ( x11-libs/libXv )
+	)
+	ffmpeg? ( media-video/ffmpeg:0= )
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg:0 )
+	openh264? ( media-libs/openh264 )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) )
+"
+
+src_prepare() {
+	cmake_src_prepare
+	echo "${PV}" > .source_version || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHANNEL_URBDRC=$(usex usb ON OFF)
+		-DWITH_ALSA=$(usex alsa ON OFF)
+		-DWITH_CCACHE=OFF
+		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
+		-DWITH_MANPAGES=$(usex doc ON OFF)
+		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_SWSCALE=$(usex ffmpeg ON OFF)
+		-DWITH_CAIRO=$(usex ffmpeg OFF ON)
+		-DWITH_DSP_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DWITH_OPENH264=$(usex openh264 ON OFF)
+		-DWITH_PULSE=$(usex pulseaudio ON OFF)
+		-DWITH_SERVER=$(usex server ON OFF)
+		-DWITH_PCSC=$(usex smartcard ON OFF)
+		-DWITH_LIBSYSTEMD=$(usex systemd ON OFF)
+		-DWITH_X11=$(usex X ON OFF)
+		-DWITH_XINERAMA=$(usex xinerama ON OFF)
+		-DWITH_XV=$(usex xv ON OFF)
+		-DWITH_WAYLAND=$(usex wayland ON OFF)
+	)
+	cmake_src_configure
+}