sci-mathematics/unuran: Port to EAPI 7

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 24 insertions, 21 deletions

diff --git a/sci-mathematics/unuran/unuran-1.8.1.ebuild b/sci-mathematics/unuran/unuran-1.8.1.ebuild
index f3fea32d662e..27d0f064189a 100644
--- a/sci-mathematics/unuran/unuran-1.8.1.ebuild
+++ b/sci-mathematics/unuran/unuran-1.8.1.ebuild
@@ -1,44 +1,47 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=7
 
-inherit autotools-utils
+inherit out-of-source
 
 DESCRIPTION="Universal Non-Uniform Random number generator"
 HOMEPAGE="http://statmath.wu.ac.at/unuran/"
-SRC_URI="${HOMEPAGE}${P}.tar.gz"
+SRC_URI="http://statmath.wu.ac.at/unuran/${P}.tar.gz"
 
 LICENSE="GPL-2"
-SLOT=0
+SLOT="0"
 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples gsl prng +rngstreams static-libs"
+IUSE="doc examples gsl prng +rngstreams"
 
 DEPEND="
-	gsl? ( sci-libs/gsl )
+	gsl? ( sci-libs/gsl:= )
 	prng? ( sci-mathematics/prng )
-	rngstreams? ( sci-mathematics/rngstreams )"
+	rngstreams? ( sci-mathematics/rngstreams:= )"
 RDEPEND="${DEPEND}"
 
-src_configure() {
+my_src_configure() {
 	local udefault=builtin
 	use rngstreams && udefault=rngstream
-	local myeconfargs=(
-		--enable-shared
-		--with-urng-default=${udefault}
-		$(use_with gsl urng-gsl)
-		$(use_with prng urng-prng)
+	econf \
+		--enable-shared \
+		--disable-static \
+		--with-urng-default="${udefault}" \
+		$(use_with gsl urng-gsl) \
+		$(use_with prng urng-prng) \
 		$(use_with rngstreams urng-rngstream)
-	)
-	autotools-utils_src_configure
 }
 
-src_install() {
-	autotools-utils_src_install
+my_src_install_all() {
 	use doc && dodoc doc/${PN}.pdf
+	einstalldocs
+
 	if use examples; then
-		rm examples/Makefile*
-		insinto /usr/share/doc/${PF}
-		doins -r examples
+		rm examples/Makefile* || die
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
 	fi
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
 }