From df7128fe1cf31726c4b40027666286c4b9f628c5 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 28 Jul 2019 17:15:18 +0200
Subject: app-editors/mousepad: Bump to 0.4.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 app-editors/mousepad/Manifest              |  1 +
 app-editors/mousepad/mousepad-0.4.2.ebuild | 51 ++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)
 create mode 100644 app-editors/mousepad/mousepad-0.4.2.ebuild

(limited to 'app-editors/mousepad')

diff --git a/app-editors/mousepad/Manifest b/app-editors/mousepad/Manifest
index bc9a70f17dfd..db97646d3bfd 100644
--- a/app-editors/mousepad/Manifest
+++ b/app-editors/mousepad/Manifest
@@ -1 +1,2 @@
 DIST mousepad-0.4.1.tar.bz2 644161 BLAKE2B 656245afb38423cff7eb8a038c8247d9023e10eb85f574f25fd4fad50b0316cbe125630ddff330adb91c49eec9ee3ed67ecd0546b9fecb065c832882b3e42145 SHA512 2ffbb4245a3344437bd41f9f28cc066ae45062f6b6d169aa274e933f033c434f0b10845ccf42ab846dcad25ae7cee36ea6619bfb6889e8cd41c994be87b77be8
+DIST mousepad-0.4.2.tar.bz2 696014 BLAKE2B 2591f177b59147e01502329939365c5f18031f3dc9100baa29cb1da04afbff26cc91cc612ea1e5ebbc2d15754375da6afbd4ae9d96399f41cf06191d7d8d7082 SHA512 f3266018ce61683dc62b6866649f3674cc363ea652de04d3f087341c61cf24fb5eb730411948e354d085792f88b59e3dba7e7712715d92711f750b33d8bfb69a
diff --git a/app-editors/mousepad/mousepad-0.4.2.ebuild b/app-editors/mousepad/mousepad-0.4.2.ebuild
new file mode 100644
index 000000000000..03b03b84cfe2
--- /dev/null
+++ b/app-editors/mousepad/mousepad-0.4.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="GTK+-based editor for the Xfce Desktop Environment"
+HOMEPAGE="https://git.xfce.org/apps/mousepad/about/"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbus +gtk3"
+# D-Bus code fails to build against GTK+2
+# https://bugzilla.xfce.org/show_bug.cgi?id=15755
+REQUIRED_USE="dbus? ( gtk3 )"
+
+RDEPEND=">=dev-libs/glib-2.42:2=
+	>=xfce-base/xfconf-4.12:=
+	!gtk3? ( >=x11-libs/gtk+-2.24:2=
+		x11-libs/gtksourceview:2.0= )
+	gtk3? ( >=x11-libs/gtk+-3.20:3=
+		x11-libs/gtksourceview:3.0= )"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	dbus? ( dev-util/gdbus-codegen )"
+
+src_configure() {
+	local myconf=(
+		$(use_enable dbus)
+		$(use_enable gtk3)
+		)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3-65-gdbad