From a0251dcffecd9a5d24d7f9e74ce1e0937f96c9f5 Mon Sep 17 00:00:00 2001
From: Victor Kustov <ktrace@yandex.ru>
Date: Tue, 5 Nov 2019 22:11:04 +0300
Subject: app-mobilephone/gammu: bump to 1.41.0

bump version

Closes: https://github.com/gentoo/gentoo/pull/13517
Closes: https://bugs.gentoo.org/696464
Signed-off-by: Victor Kustov <ktrace@yandex.ru>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 app-mobilephone/gammu/Manifest            |  1 +
 app-mobilephone/gammu/gammu-1.41.0.ebuild | 62 +++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 app-mobilephone/gammu/gammu-1.41.0.ebuild

(limited to 'app-mobilephone/gammu')

diff --git a/app-mobilephone/gammu/Manifest b/app-mobilephone/gammu/Manifest
index 6e23505067db..fc0664db76a6 100644
--- a/app-mobilephone/gammu/Manifest
+++ b/app-mobilephone/gammu/Manifest
@@ -1,3 +1,4 @@
 DIST gammu-1.38.5.tar.bz2 2138742 BLAKE2B 7a72a7b67475f73dc3580d618dee379893dc82d7950599b41ed1f7efb5fecd80af3a42a0cc0742cb73d055a4a778eaa4d42037c5be74d9b61a4b53cfe827bd00 SHA512 89a6b3872dfd9b4ebaf8b0f51265fec7e7ef72a42178f85846c7f52d926e96b3087bbe6650c4246e66c2624822021c5803b1bb6ca8ac90f3e5c109a644c0ee80
 DIST gammu-1.39.0.tar.bz2 2151226 BLAKE2B 0e9b7a3f5321a166bbafe833134f49ac8dc93a68c5522be1c16e5ceb894cb242b644761a90188fbc9fa9dd62bde51828a72b29d09fc37b2aa2911d301dffac39 SHA512 ed8994f6ec25d8ddbed23680e8a02db05c8e7f85aa6b8c0d409b5e8377e7c9e07fc61e62d80f6741d648709fb58a10ec631155d8b1ffc1c7d3b6e425cf53c797
 DIST gammu-1.40.0.tar.bz2 2156194 BLAKE2B b030e1293eaf1aeb38a553d45507ec2c3b4ba9ae34e7cb6589a60bd34451b545cc8e1f7bebfe28c9c1a12c89cecedeac17ffe27ddffab27c274590801b2091dc SHA512 6dbab68f30567a501487cf4edf19e23b7b23b7b78e3dfff69fc8d3c95b62f74ee14fe25ca380eac071e67f1a523dfd69cb9137fe049bf6477dfcc94930b71ce9
+DIST gammu-1.41.0.tar.bz2 2167233 BLAKE2B 4b0bf77246cc6a07a52457cff2bae44e63ebfe2715cb0c0b7d89c3d6352bb2df4cd5e7fd9b62d316e316fb1e73108fe561e030b7444eccd601cd0d2541b9f0e9 SHA512 f2c2534d3827216bf015607431938e0cf2524d5f2c670a5f76bb5ab7928962d22de981bbbf2dfa7af833c7903b60a775242048210bac6c35b1a9ee7668db4543
diff --git a/app-mobilephone/gammu/gammu-1.41.0.ebuild b/app-mobilephone/gammu/gammu-1.41.0.ebuild
new file mode 100644
index 000000000000..8be8100b03e1
--- /dev/null
+++ b/app-mobilephone/gammu/gammu-1.41.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="A tool to handle your cellular phone"
+HOMEPAGE="https://wammu.eu/gammu/"
+SRC_URI="https://dl.cihar.com/${PN}/releases/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bluetooth curl dbi debug irda mysql nls odbc postgres usb"
+
+DEPEND="
+	dev-libs/glib:2=
+	virtual/libgudev:=
+	virtual/libiconv
+	bluetooth? ( net-wireless/bluez:= )
+	curl? ( net-misc/curl:= )
+	dbi? ( >=dev-db/libdbi-0.8.3:= )
+	irda? ( virtual/os-headers )
+	mysql? ( dev-db/mysql-connector-c:= )
+	nls? ( sys-devel/gettext )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( dev-db/postgresql:= )
+	usb? ( virtual/libusb:1= )
+"
+
+RDEPEND="
+	${DEPEND}
+	dev-util/dialog
+"
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_BLUETOOTH=$(usex bluetooth)
+		-DWITH_CURL=$(usex curl)
+		-DWITH_Gettext=$(usex nls)
+		-DWITH_Iconv=$(usex nls)
+		-DWITH_IRDA=$(usex irda)
+		-DWITH_LibDBI=$(usex dbi)
+		-DWITH_MySQL=$(usex mysql)
+		-DWITH_ODBC=$(usex odbc)
+		-DWITH_Postgres=$(usex postgres)
+		-DWITH_USB=$(usex usb)
+		-DBUILD_SHARED_LIBS=ON
+		-DINSTALL_DOC_DIR="share/doc/${PF}"
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	addwrite "/run/lock/LCK..bar"
+	LD_LIBRARY_PATH="${BUILD_DIR}/libgammu" cmake-utils_src_test -j1
+}
+
+src_install() {
+	cmake-utils_src_install
+	docompress -x /usr/share/doc/${PF}/examples/
+}
-- 
cgit v1.2.3-65-gdbad