From 44f56d6430cf8b1d5adb47494ea1e2b609d70f31 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 16 Aug 2022 23:40:39 +0200
Subject: dev-embedded/avrdude: drop 6.3, EAPI-6--

Closes: https://bugs.gentoo.org/832769
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-embedded/avrdude/avrdude-6.3.ebuild | 62 ---------------------------------
 1 file changed, 62 deletions(-)
 delete mode 100644 dev-embedded/avrdude/avrdude-6.3.ebuild

(limited to 'dev-embedded/avrdude')

diff --git a/dev-embedded/avrdude/avrdude-6.3.ebuild b/dev-embedded/avrdude/avrdude-6.3.ebuild
deleted file mode 100644
index 6e1f5db129f9..000000000000
--- a/dev-embedded/avrdude/avrdude-6.3.ebuild
+++ /dev/null
@@ -1,62 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit toolchain-funcs
-
-DESCRIPTION="AVR Downloader/UploaDEr"
-HOMEPAGE="https://savannah.nongnu.org/projects/avrdude"
-SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz
-	doc? (
-		mirror://nongnu/${PN}/${PN}-doc-${PV}.tar.gz
-		mirror://nongnu/${PN}/${PN}-doc-${PV}.pdf
-	)"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 arm ppc ppc64 x86"
-IUSE="doc ftdi ncurses readline"
-
-RDEPEND="virtual/libusb:1
-	virtual/libusb:0
-	ftdi? ( dev-embedded/libftdi:= )
-	ncurses? ( sys-libs/ncurses:0= )
-	readline? ( sys-libs/readline:0= )"
-DEPEND="${RDEPEND}"
-
-DOCS="AUTHORS ChangeLog* NEWS README"
-
-src_prepare() {
-	default
-
-	# let the build system re-generate these, bug #120194
-	rm -f lexer.c config_gram.c config_gram.h || die
-}
-
-src_configure() {
-	# somehow this doesnt get set when cross-compiling and breaks build
-	tc-export AR
-	export ac_cv_lib_ftdi_ftdi_usb_get_strings=$(usex ftdi)
-	export ac_cv_lib_ncurses_tputs=$(usex ncurses)
-	export ac_cv_lib_readline_readline=$(usex readline)
-	econf --disable-static
-}
-
-src_compile() {
-	# The automake target for these files does not use tempfiles or create
-	# these atomically, confusing a parallel build. So we force them first.
-	emake lexer.c config_gram.c config_gram.h
-	emake
-}
-
-src_install() {
-	default
-
-	if use doc ; then
-		newdoc "${DISTDIR}/${PN}-doc-${PV}.pdf" avrdude.pdf
-		dodoc -r "${WORKDIR}/avrdude-html/"
-	fi
-
-	find "${ED}" -name '*.la' -delete || die
-}
-- 
cgit v1.2.3-65-gdbad