From 0fbd3b86a0e4e00a816eb474e0242c4fe2464970 Mon Sep 17 00:00:00 2001
From: Patrick McLean <chutzpah@gentoo.org>
Date: Wed, 29 May 2024 17:42:57 -0700
Subject: dev-python/pypax: Revbump, add py312 (bug #929492)

Closes: https://bugs.gentoo.org/929492
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 dev-python/pypax/pypax-0.9.5-r2.ebuild | 47 ++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-python/pypax/pypax-0.9.5-r2.ebuild

(limited to 'dev-python/pypax')

diff --git a/dev-python/pypax/pypax-0.9.5-r2.ebuild b/dev-python/pypax/pypax-0.9.5-r2.ebuild
new file mode 100644
index 000000000000..d4c2e380a5e2
--- /dev/null
+++ b/dev-python/pypax/pypax-0.9.5-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit distutils-r1
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/elfix.git"
+	inherit git-r3
+else
+	SRC_URI="https://dev.gentoo.org/~blueness/elfix/elfix-${PV}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	S="${WORKDIR}/elfix-${PV}"
+fi
+
+DESCRIPTION="Python module to get or set either PT_PAX and/or XATTR_PAX flags"
+HOMEPAGE="https://dev.gentoo.org/~blueness/elfix/
+	https://wiki.gentoo.org/wiki/Project:Hardened/PaX_Quickstart"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+ptpax +xtpax"
+REQUIRED_USE="|| ( ptpax xtpax )"
+
+RDEPEND="
+	ptpax? ( dev-libs/elfutils )
+	xtpax? ( sys-apps/attr )"
+DEPEND="${RDEPEND}"
+
+src_compile() {
+	cd scripts || die
+	unset PTPAX
+	unset XTPAX
+	use ptpax && export PTPAX="yes"
+	use xtpax && export XTPAX="yes"
+	distutils-r1_src_compile
+}
+
+src_install() {
+	cd scripts || die
+	distutils-r1_src_install
+}
-- 
cgit v1.2.3-65-gdbad