From 888e9aa0168d733e3afaf7bc30e58761f5b31873 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sun, 25 Oct 2015 15:20:07 +0100
Subject: games-engines/scummvm-tools: Support wxGTK:3.0

Package-Manager: portage-2.2.23
---
 .../scummvm-tools/scummvm-tools-1.7.0-r1.ebuild    | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 games-engines/scummvm-tools/scummvm-tools-1.7.0-r1.ebuild

(limited to 'games-engines/scummvm-tools')

diff --git a/games-engines/scummvm-tools/scummvm-tools-1.7.0-r1.ebuild b/games-engines/scummvm-tools/scummvm-tools-1.7.0-r1.ebuild
new file mode 100644
index 000000000000..6c675feaec69
--- /dev/null
+++ b/games-engines/scummvm-tools/scummvm-tools-1.7.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+WX_GTK_VER=3.0
+inherit wxwidgets eutils flag-o-matic games
+
+DESCRIPTION="utilities for the SCUMM game engine"
+HOMEPAGE="http://scummvm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/scummvm/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="flac iconv mad png vorbis"
+RESTRICT="test" # some tests require external files
+
+RDEPEND="png? ( media-libs/libpng:0 )
+	mad? ( media-libs/libmad )
+	flac? ( media-libs/flac )
+	vorbis? ( media-libs/libvorbis )
+	iconv? ( virtual/libiconv media-libs/freetype:2 )
+	sys-libs/zlib
+	>=dev-libs/boost-1.32
+	x11-libs/wxGTK:${WX_GTK_VER}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	need-wxwidgets unicode
+	rm -rf *.bat dists/win32
+	sed -ri -e '/^(CC|CXX)\b/d' Makefile || die
+	epatch "${FILESDIR}/${P}-binprefix.patch"
+}
+
+src_configure() {
+	# Not an autoconf script
+	./configure \
+		--enable-verbose-build \
+		--mandir=/usr/share/man \
+		--prefix="${GAMES_PREFIX}" \
+		--libdir="${GAMES_PREFIX}/lib" \
+		--datadir="${GAMES_DATADIR}" \
+		$(use_enable flac) \
+		$(use_enable iconv) \
+		$(use_enable iconv freetype) \
+		$(use_enable mad) \
+		$(use_enable png) \
+		$(use_enable vorbis) || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" EXEPREFIX="${PN}-" install
+	dodoc README TODO
+	prepgamesdirs
+}
-- 
cgit v1.2.3-65-gdbad