From ebc9c12fb827d5ea188e34fa9dc5fbfcb425a234 Mon Sep 17 00:00:00 2001
From: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
Date: Sat, 1 Apr 2023 17:25:51 +0200
Subject: media-libs/intel-mediasdk: add 23.1.5

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
---
 media-libs/intel-mediasdk/Manifest                 |  1 +
 .../intel-mediasdk/intel-mediasdk-23.1.5.ebuild    | 86 ++++++++++++++++++++++
 2 files changed, 87 insertions(+)
 create mode 100644 media-libs/intel-mediasdk/intel-mediasdk-23.1.5.ebuild

(limited to 'media-libs/intel-mediasdk')

diff --git a/media-libs/intel-mediasdk/Manifest b/media-libs/intel-mediasdk/Manifest
index 2f88530fc829..acfeab89c0e9 100644
--- a/media-libs/intel-mediasdk/Manifest
+++ b/media-libs/intel-mediasdk/Manifest
@@ -1,3 +1,4 @@
 DIST intel-mediasdk-22.6.5.tar.gz 11657890 BLAKE2B 53b38f7b3757895f65badb7e43e5d1f1112f744dd4a43ea9313f7bfbdf889088310b2093ccd45794426f0ac5e38ca8d901790d4963945648a3b99922476d02e0 SHA512 af9a59a9a7e9477672a875f454988cc49d8b782b32701ba681efa6dda445239e133b00f9366fc58ddadf79beef0ee74f1165990f0b8194124a841b36d5dca6bc
 DIST intel-mediasdk-23.1.2.tar.gz 11658547 BLAKE2B fb4314bb539630090594835b869c19c639097305cb3b72a14fca2c8b0e429c1c73a9736460db5852d4e2899efbca9aac076f8ff37da0851ac078ece913dab6ad SHA512 1f6a31197fc1f2670f36e1602cc7a194a02cd809470c7f4de630d68f0cbf9b643207491ce2f3c5b2d94af8843bfb9383d202e0f2ea8552e48307b7ad15a0cbb6
 DIST intel-mediasdk-23.1.3.tar.gz 11657956 BLAKE2B 69aeed5c706381571c03f5e62471ee6494182b181c682f959cfde88294d132872674aa04e59f91ac02718a87b2c9155122d72719dcffa23f441c21c3de9cea76 SHA512 560ac33ce6afaf078ae004d9d73ac4614b68596f961a1068bded738b4c4564c133b94a0f2b32b8c54a76ea70f0db2fcf21a68f74f59a3a3efe063d7c73ec6f29
+DIST intel-mediasdk-23.1.5.tar.gz 11657487 BLAKE2B c86fef7a53f706f124f22ecc85f7fa93ecd5b828f01ade1fca9053867880b54f75b945e0054a408d42abccff14d9727927e8137c68de5b22e3f52a42fd2c1c68 SHA512 65444c903a3c2be0d890d42802f5b00caba109e7b7e3f2b165daaae2d37584fb31a9bd697a955273fee96c3d0a16af4ee7b16ee24c4c83c085b3cb76d209ae1d
diff --git a/media-libs/intel-mediasdk/intel-mediasdk-23.1.5.ebuild b/media-libs/intel-mediasdk/intel-mediasdk-23.1.5.ebuild
new file mode 100644
index 000000000000..61173b80745c
--- /dev/null
+++ b/media-libs/intel-mediasdk/intel-mediasdk-23.1.5.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+	: ${EGIT_REPO_URI:="https://github.com/Intel-Media-SDK/MediaSDK"}
+	if [[ ${PV%9999} != "" ]] ; then
+		: ${EGIT_BRANCH:="release/${PV%.9999}"}
+	fi
+	inherit git-r3
+fi
+
+DESCRIPTION="Intel Media SDK"
+HOMEPAGE="https://github.com/Intel-Media-SDK/MediaSDK"
+if [[ ${PV} == *9999 ]] ; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Intel-Media-SDK/MediaSDK/archive/intel-mediasdk-${PV}.tar.gz"
+	S="${WORKDIR}/MediaSDK-intel-mediasdk-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+IUSE="dri test tools wayland X"
+# Test not working at the moment
+#RESTRICT="!test? ( test )"
+RESTRICT="test"
+REQUIRED_USE="
+	dri? ( X )
+"
+
+# x11-libs/libdrm[video_cards_intel] for intel_bufmgr.h in samples
+# bug #805224
+RDEPEND="
+	x11-libs/libpciaccess[${MULTILIB_USEDEP}]
+	>=media-libs/libva-intel-media-driver-${PV}[${MULTILIB_USEDEP}]
+	media-libs/libva[X?,wayland?,${MULTILIB_USEDEP}]
+	x11-libs/libdrm[video_cards_intel,${MULTILIB_USEDEP}]
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+	)
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libxcb[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		dev-libs/wayland-protocols
+	)
+"
+BDEPEND="
+	wayland? (
+		dev-util/wayland-scanner
+	)
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		# OpenCL only has an effect if we build kernels
+		-DENABLE_OPENCL=OFF
+		-DBUILD_TUTORIALS=OFF
+		# Need to package the cm-compiler to build kernels, use pre-built instead
+		-DBUILD_KERNELS=OFF
+		-DBUILD_RUNTIME=ON
+		-DBUILD_DISPATCHER=ON
+		-DBUILD_TOOLS="$(usex tools)"
+		# Cannot build tools without samples
+		-DBUILD_SAMPLES="$(usex tools)"
+		-DBUILD_TESTS="$(usex test)"
+		-DENABLE_X11="$(usex X)"
+		-DENABLE_X11_DRI3="$(usex dri)"
+		-DENABLE_WAYLAND="$(usex wayland)"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	optfeature "Intel GPUs newer then, and including, Intel Xe" media-libs/oneVPL-intel-gpu
+}
-- 
cgit v1.2.3-65-gdbad