blob: ff7e0ac8d26a1aaca669ec3573a31736908b717b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
DESCRIPTION="Free UCI chess engine, claimed to be the strongest in the world"
HOMEPAGE="https://stockfishchess.org/"
NNUE_FILE="nn-5af11540bbfe.nnue"
SRC_URI="https://github.com/official-stockfish/Stockfish/archive/sf_${PV}.tar.gz -> ${P}.tar.gz
https://tests.stockfishchess.org/api/nn/${NNUE_FILE} -> ${P}-${NNUE_FILE}"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~loong ~riscv ~x86"
IUSE="cpu_flags_arm_v7 cpu_flags_x86_avx2 cpu_flags_x86_popcnt cpu_flags_x86_sse cpu_flags_x86_avx512f
cpu_flags_x86_avx512dq debug general-32 general-64 +optimize"
DEPEND="|| ( app-arch/unzip app-arch/zip )"
S="${WORKDIR}/Stockfish-sf_${PV}/src"
pkg_setup() {
if ! tc-is-clang && ! tc-is-gcc; then
die "Unsupported compiler: $(tc-getCC)"
fi
}
src_prepare() {
default
# remove config sanity check that doesn't like our COMPILER settings
sed -i -e 's/ config-sanity//g' Makefile || die
cp "${DISTDIR}"/${P}-${NNUE_FILE} ${NNUE_FILE} || die "copying the nnue file failed"
# prevent pre-stripping
sed -e 's:-strip $(BINDIR)/$(EXE)::' -i Makefile \
|| die 'failed to disable stripping in the Makefile'
# Makefile is a bit optimistic
sed -e 's:-flto=full:-flto:g' -i Makefile || die
}
src_compile() {
local my_arch
# generic unoptimized first
use general-32 && my_arch=general-32
use general-64 && my_arch=general-64
# x86
use x86 && my_arch=x86-32-old
use cpu_flags_x86_sse && my_arch=x86-32
# amd64
use amd64 && my_arch=x86-64
use cpu_flags_x86_popcnt && my_arch=x86-64-modern
# both bmi2 and avx2 are part of hni (haswell new instructions)
use cpu_flags_x86_avx2 && my_arch=x86-64-bmi2
# avx512
# we currently can't express 'avx512vnni' 'avx512dq' 'avx512f' 'avx512bw' 'avx512vl'
# so only enable basic support
use cpu_flags_x86_avx512f && use cpu_flags_x86_avx512dq && my_arch=x86-64-avx512
# other architectures
use cpu_flags_arm_v7 && my_arch=armv7
use ppc && my_arch=ppc
use ppc64 && my_arch=ppc64
# Bug 919781: COMP is a fixed string like clang/gcc to set tools for PGO
local comp
tc-is-gcc && comp="gcc"
tc-is-clang && comp="clang"
# There's a nice hack in the Makefile that overrides the value of CXX with
# COMPILER to support Travis CI and we abuse it to make sure that we
# build with our compiler of choice.
emake profile-build ARCH="${my_arch}" \
COMP="${comp}" \
COMPILER="$(tc-getCXX)" \
debug=$(usex debug "yes" "no") \
optimize=$(usex optimize "yes" "no")
}
src_install() {
dobin "${PN}"
dodoc ../AUTHORS ../README.md
}
|
GitWeb