blob: 133633c129f98074d1d78f047a8a13619f7d03ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools gnome.org multilib-minimal
DESCRIPTION="An elegant API for accessing audio files"
HOMEPAGE="https://audiofile.68k.org/"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0/1" # subslot = soname major version
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
IUSE="flac"
RDEPEND="flac? ( >=media-libs/flac-1.2.1:=[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-0.3.6-gcc6-build-fixes.patch
"${FILESDIR}"/${PN}-0.3.6-CVE-2015-7747.patch
"${FILESDIR}"/${PN}-0.3.6-mingw32.patch
"${FILESDIR}"/${PN}-0.3.6-CVE-2017-68xx.patch
"${FILESDIR}"/${PN}-0.3.6-CVE-2018-13440-CVE-2018-17095.patch
"${FILESDIR}"/${PN}-0.3.6-strict-prototypes.patch
"${FILESDIR}"/${PN}-0.3.6-clang-deprecation.patch
)
src_prepare() {
default
eautoreconf
}
multilib_src_configure() {
# Tests depend on statically compiled binaries to work, so we'll have to
# delete them later rather than not compile them at all
local myconf=(
--enable-largefile
# static needed for tests, bug #869677
--enable-static
--disable-werror
--disable-examples
$(use_enable flac)
)
ECONF_SOURCE="${S}" econf "${myconf[@]}"
}
multilib_src_test() {
emake check
}
multilib_src_install_all() {
einstalldocs
# package provides .pc file
find "${ED}" -name '*.la' -delete || die
find "${ED}" -name '*.a' -delete || die
}
|
GitWeb
