blob: 6c88ea4ac1a5a5ccd2bd5b6b7b1273efb71cc3e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python{2_7,3_5,3_6} )
inherit python-any-r1 scons-utils toolchain-funcs
DESCRIPTION="An advanced command-line based metronome for JACK"
HOMEPAGE="http://das.nasophon.de/klick"
SRC_URI="http://das.nasophon.de/download/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug osc rubberband"
RDEPEND="dev-libs/boost
media-libs/libsamplerate
media-libs/libsndfile
virtual/jack
osc? ( media-libs/liblo )
rubberband? ( media-libs/rubberband )"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${P}-sconstruct.patch
"${FILESDIR}"/${P}-gcc6.patch
)
HTML_DOCS=( doc/manual.html )
src_configure() {
MYSCONS=(
CXX="$(tc-getCXX)"
CXXFLAGS="${CXXFLAGS}"
LINKFLAGS="${LDFLAGS}"
PREFIX="${EPREFIX}/usr"
DESTDIR="${D}"
DEBUG=$(usex debug)
OSC=$(usex osc)
RUBBERBAND=$(usex rubberband)
)
}
src_compile() {
escons "${MYSCONS[@]}"
}
src_install() {
escons "${MYSCONS[@]}" install
einstalldocs
}
|
GitWeb
