blob: 3aa8309bf12366e7fad66c49a6d12f20d4b30ef3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
OC_COMMIT=119fe41a83bc455a24a11ecc9b78e7b13fcfcc45
GT_COMMIT=2ad076167a676e3ed62f90b754b30fac5caa1f88
PYTHON_COMPAT=( python3_{10..11} )
inherit flag-o-matic python-single-r1 cmake
DESCRIPTION="Simple Theorem Prover, an efficient SMT solver for bitvectors"
HOMEPAGE="https://stp.github.io/
https://github.com/stp/stp/"
SRC_URI="
https://github.com/stp/stp/archive/${PV}.tar.gz
-> ${P}.tar.gz
test? (
https://github.com/stp/OutputCheck/archive/${OC_COMMIT}.tar.gz
-> ${P}_OutputCheck.tar.gz
https://github.com/stp/googletest/archive/${GT_COMMIT}.tar.gz
-> ${P}_gtest.tar.gz
)
"
LICENSE="GPL-2+ MIT"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~x86"
IUSE="cryptominisat debug +python test"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
RDEPEND="
dev-libs/boost:=
sci-mathematics/minisat:=
sys-libs/zlib:=
cryptominisat? (
dev-db/sqlite:3
dev-libs/icu:=
sci-mathematics/cryptominisat:=
)
python? ( ${PYTHON_DEPS} )
"
DEPEND="${RDEPEND}"
BDEPEND="
sys-apps/help2man
test? ( dev-python/lit )
"
PATCHES=(
"${FILESDIR}"/${P}-CMakeLists.txt-fix_cflags.patch
"${FILESDIR}"/${P}-cstdint.patch
"${FILESDIR}"/${P}-stp.py-library_path.patch
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_unpack() {
unpack ${P}.tar.gz
if use test ; then
local i
for i in OutputCheck gtest ; do
tar xf "${DISTDIR}"/${P}_${i}.tar.gz --strip-components=1 \
-C "${S}"/utils/${i} || die "failed to unpack ${i}"
done
fi
}
src_prepare() {
# Replace static lib with get_libdir
sed -i "s/set(LIBDIR lib/set(LIBDIR $(get_libdir)/" CMakeLists.txt || die
# Remove problematic test
rm "${S}"/tests/query-files/misc-tests/no-query.cvc || die
cmake_src_prepare
}
src_configure() {
# -Werror=odr warnings, bug #863263
filter-lto
local CMAKE_BUILD_TYPE
if use debug ; then
CMAKE_BUILD_TYPE=Debug
else
CMAKE_BUILD_TYPE=Release
fi
local -a mycmakeargs=(
-DTEST_C_API=OFF # C API test fail
-DNOCRYPTOMINISAT=$(usex cryptominisat 'OFF' 'ON') # double negation
-DENABLE_PYTHON_INTERFACE=$(usex python)
-DENABLE_ASSERTIONS=$(usex test)
-DENABLE_TESTING=$(usex test)
)
cmake_src_configure
}
src_install() {
cmake_src_install
# Because Python files for tests (in BUILD_DIR) and those installed on the
# system differ, and are generated upon install, we have to wait for CMake
# to install them into the temporary image.
use python && python_optimize "${D}/$(python_get_sitedir)"/stp
mv "${D}"/usr/man "${D}"/usr/share/man || die
dodoc -r papers
}
|
GitWeb