x11-misc/vym/vym-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
inherit eutils cmake-utils git-r3

DESCRIPTION="View Your Mind, a mindmap tool"
HOMEPAGE="http://www.insilmaril.de/vym/"
EGIT_REPO_URI="git://git.code.sf.net/p/vym/code"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="dbus"

VYM_LINGUAS=( cs_CZ de_DE es fr ia it pt_BR ru sv zh_CN zh_TW )
IUSE+=" ${VYM_LINGUAS[@]/#/linguas_}"

DEPEND="
	dev-qt/qtgui:4[qt3support]
	dev-qt/qtsvg:4
	dbus? ( dev-qt/qtdbus:4 )
"
RDEPEND="
	${DEPEND}
	app-arch/zip
"

DOCS=( README.txt )

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.3.22-arrowobj.patch

	sed -i \
		-e '/lang\/vym_en.ts/d' \
		CMakeLists.txt || die
	rm -r lang/vym_en.ts || die
}

src_configure() {
	local lingua
	for lingua in ${VYM_LINGUAS[@]}; do
		if ! use linguas_${lingua}; then
			sed -i -e "/lang\/vym_${lingua}.ts/d" CMakeLists.txt || die
			rm -r lang/vym_${lingua}.ts || die
		fi
	done

	local mycmakeargs=(
		$(cmake-utils_use !dbus NO_DBUS)
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	doman doc/vym.1.gz
	make_desktop_entry vym vym /usr/share/vym/icons/vym.png Education
}