From a5b4929c5b39b7a2a2d0444ef8076826a9209336 Mon Sep 17 00:00:00 2001
From: Elijah El Lazkani <ThyArmageddon+GentooOverlay@Gmail.com>
Date: Tue, 26 Jun 2012 22:48:34 -0400
Subject: Added latest tomahawk stable release 0.5.0 forked from the live...

---
 media-sound/tomahawk/Manifest              |  1 +
 media-sound/tomahawk/tomahawk-0.5.0.ebuild | 85 ++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)
 create mode 100644 media-sound/tomahawk/Manifest
 create mode 100644 media-sound/tomahawk/tomahawk-0.5.0.ebuild

diff --git a/media-sound/tomahawk/Manifest b/media-sound/tomahawk/Manifest
new file mode 100644
index 0000000..d1a78a0
--- /dev/null
+++ b/media-sound/tomahawk/Manifest
@@ -0,0 +1 @@
+DIST tomahawk-0.5.0.tar.bz2 4848360 RMD160 91b8c839d89f833662fccf44d4bd4e454f46e969 SHA1 b11db5951aba800723132459e0a99004c2977726 SHA256 f36d3825f47e485b8e014593c0d16d245469f157f28446910a021c37af93369a
diff --git a/media-sound/tomahawk/tomahawk-0.5.0.ebuild b/media-sound/tomahawk/tomahawk-0.5.0.ebuild
new file mode 100644
index 0000000..997ed1d
--- /dev/null
+++ b/media-sound/tomahawk/tomahawk-0.5.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/tomahawk/tomahawk-9999.ebuild,v 1.6 2012/04/06 08:44:31 scarabeus Exp $
+
+EAPI=4
+
+QT_MINIMAL="4.7.0"
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="http://download.tomahawk-player.org/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	GIT_ECLASS="git-2"
+	EGIT_REPO_URI="git://github.com/tomahawk-player/tomahawk.git"
+	KEYWORDS=""
+fi
+
+inherit cmake-utils qt4-r2 ${GIT_ECLASS}
+
+DESCRIPTION="Qt playdar social music player"
+HOMEPAGE="http://tomahawk-player.org/"
+
+LICENSE="GPL-3 BSD"
+SLOT="0"
+IUSE="debug fftw jabber libsamplerate +resolver twitter"
+
+DEPEND="
+	app-crypt/qca
+	>=dev-cpp/clucene-2.3.3.4
+	>=dev-libs/boost-1.41
+	>=dev-libs/qjson-0.7.1
+	>=media-libs/libechonest-1.1.10
+	>=media-libs/liblastfm-1.0.0
+	>=media-libs/phonon-4.5.0
+	media-libs/taglib
+	>=x11-libs/qt-core-${QT_MINIMAL}:4
+	>=x11-libs/qt-gui-${QT_MINIMAL}:4
+	>=x11-libs/qt-sql-${QT_MINIMAL}:4[sqlite]
+	>=x11-libs/qt-webkit-${QT_MINIMAL}:4
+	>=x11-libs/qt-xmlpatterns-${QT_MINIMAL}:4
+	fftw? ( sci-libs/fftw:3.0 )
+	jabber? ( net-libs/jreen )
+	libsamplerate? ( media-libs/libsamplerate )
+	resolver? (
+		>=dev-libs/libattica-0.4.0
+		>=dev-libs/quazip-0.4.3
+	)
+	twitter? ( net-libs/qtweetlib )
+"
+RDEPEND="${DEPEND}
+	app-crypt/qca-ossl
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with jabber Jreen)
+		$(cmake-utils_use_with resolver LibAttica)
+		$(cmake-utils_use_with resolver QuaZip)
+		$(cmake-utils_use_with twitter QTweetLib)
+		-DINTERNAL_JREEN=OFF
+	)
+
+	if [[ ${PV} != *9999* ]]; then
+		mycmakeargs+=(	-DBUILD_RELEASE=ON )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	if ! use resolver; then
+		echo
+		elog "Information on how to get more resolvers for ${PN}"
+		elog "is available at ${HOMEPAGE}resolvers"
+		echo
+	fi
+}
-- 
cgit v1.2.3-65-gdbad