Version bump.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 72 insertions, 1 deletions

diff --git a/dev-util/dialog/ChangeLog b/dev-util/dialog/ChangeLog
index 2284fe310a5b..c120aaafd739 100644
--- a/dev-util/dialog/ChangeLog
+++ b/dev-util/dialog/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/dialog
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.169 2012/12/16 17:28:18 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.170 2012/12/31 17:44:01 jer Exp $
+
+*dialog-1.2.20121230 (31 Dec 2012)
+
+  31 Dec 2012; Jeroen Roovers <jer@gentoo.org> +dialog-1.2.20121230.ebuild:
+  Version bump.
 
   16 Dec 2012; Raúl Porcel <armin76@gentoo.org> dialog-1.1.20120706.ebuild:
   alpha/ia64/m68k/s390/sh/sparc stable wrt #440652
diff --git a/dev-util/dialog/dialog-1.2.20121230.ebuild b/dev-util/dialog/dialog-1.2.20121230.ebuild
new file mode 100644
index 000000000000..43ae1c67559f
--- /dev/null
+++ b/dev-util/dialog/dialog-1.2.20121230.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/dialog-1.2.20121230.ebuild,v 1.1 2012/12/31 17:44:01 jer Exp $
+
+EAPI="4"
+
+inherit multilib eutils
+
+MY_PV="${PV/1.2./1.2-}"
+S=${WORKDIR}/${PN}-${MY_PV}
+DESCRIPTION="tool to display dialog boxes from a shell"
+HOMEPAGE="http://invisible-island.net/dialog/dialog.html"
+SRC_URI="ftp://invisible-island.net/${PN}/${PN}-${MY_PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="examples minimal nls static-libs unicode"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.2-r5
+	unicode? ( sys-libs/ncurses[unicode] )
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	!minimal? ( sys-devel/libtool )
+	!<=sys-freebsd/freebsd-contrib-8.9999
+"
+
+src_prepare() {
+	sed -i configure -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' || die
+	sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-rpath-hack \
+		$(use_enable nls) \
+		$(use_with !minimal libtool) \
+		--with-libtool-opts=$(usex static-libs '' '-shared') \
+		--with-ncurses$(usex unicode w '')
+}
+
+src_install() {
+	if use minimal; then
+		emake DESTDIR="${D}" install
+	else
+		emake DESTDIR="${D}" install-full
+	fi
+
+	dodoc CHANGES README
+
+	if use examples; then
+		docinto samples
+		dodoc $( find samples -maxdepth 1 -type f )
+		docinto samples/copifuncs
+		dodoc $( find samples/copifuncs -maxdepth 1 -type f )
+		docinto samples/install
+		dodoc $( find samples/install -type f )
+	fi
+
+	if ! use static-libs; then
+		rm -f "${ED}"usr/$(get_libdir)/libdialog.{la,a}
+	fi
+}