Add multilib support, bug#493974, thanks to Michael Mair-Keimberger (iamnr3) and austinenglish

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key BF20DC51)

2 files changed, 62 insertions, 2 deletions

diff --git a/dev-libs/nettle/ChangeLog b/dev-libs/nettle/ChangeLog
index f8a63e157b24..8e0f30c6b4a6 100644
--- a/dev-libs/nettle/ChangeLog
+++ b/dev-libs/nettle/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/nettle
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/ChangeLog,v 1.102 2013/08/06 13:07:05 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/ChangeLog,v 1.103 2014/02/15 21:44:55 alonbl Exp $
+
+*nettle-2.7.1-r1 (15 Feb 2014)
+
+  15 Feb 2014; Alon Bar-Lev <alonbl@gentoo.org> +nettle-2.7.1-r1.ebuild:
+  Add multilib support, bug#493974, thanks to Michael Mair-Keimberger (iamnr3)
+  and austinenglish
 
   06 Aug 2013; Agostino Sarubbo <ago@gentoo.org> nettle-2.7.1.ebuild:
   Stable for s390, wrt bug #477612
diff --git a/dev-libs/nettle/nettle-2.7.1-r1.ebuild b/dev-libs/nettle/nettle-2.7.1-r1.ebuild
new file mode 100644
index 000000000000..de66f87334f1
--- /dev/null
+++ b/dev-libs/nettle/nettle-2.7.1-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/nettle-2.7.1-r1.ebuild,v 1.1 2014/02/15 21:44:55 alonbl Exp $
+
+EAPI=5
+
+inherit eutils autotools-multilib multilib
+
+DESCRIPTION="Low-level cryptographic library"
+HOMEPAGE="http://www.lysator.liu.se/~nisse/nettle/"
+SRC_URI="http://www.lysator.liu.se/~nisse/archive/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-3 LGPL-2.1 )"
+SLOT="0/4" # subslot = libnettle soname version
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="doc +gmp neon static-libs test"
+
+DEPEND="gmp? ( dev-libs/gmp )"
+RDEPEND="${DEPEND}
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20131008-r9
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.7-shared.patch
+
+	sed -e '/CFLAGS=/s: -ggdb3::' \
+		-e 's/solaris\*)/sunldsolaris*)/' \
+		-i configure.ac || die
+
+	# conditionally build tests and examples required by tests
+	use test || sed -i '/SUBDIRS/s/testsuite examples//' Makefile.in || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# --disable-openssl bug #427526
+	ECONF_SOURCE="${S}" econf \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		$(use_enable gmp public-key) \
+		$(use_enable static-libs static) \
+		--disable-openssl \
+		$(use_enable doc documentation) \
+		$(use_enable neon arm-neon)
+}
+
+multilib_src_install_all() {
+	if use doc ; then
+		dohtml nettle.html
+		dodoc nettle.pdf
+	fi
+}