* New version for GNOME 2.24. Bug fixes and uses gnome-session D-Bus API for logout/shutdown (might require gnome-session 2.24).

(Portage version: 2.2_rc12/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

2 files changed, 81 insertions, 1 deletions

diff --git a/gnome-base/gnome-panel/ChangeLog b/gnome-base/gnome-panel/ChangeLog
index 57af6519877e..7bb78c9390a6 100644
--- a/gnome-base/gnome-panel/ChangeLog
+++ b/gnome-base/gnome-panel/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-base/gnome-panel
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.258 2008/09/25 15:21:42 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.259 2008/11/06 23:44:11 eva Exp $
+
+*gnome-panel-2.24.1 (06 Nov 2008)
+
+  06 Nov 2008; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-panel-2.24.1.ebuild:
+  New version for GNOME 2.24. Bug fixes and uses gnome-session D-Bus API for
+  logout/shutdown (might require gnome-session 2.24).
 
   25 Sep 2008; Jeroen Roovers <jer@gentoo.org> gnome-panel-2.22.2.ebuild:
   Stable for HPPA (bug #236971).
diff --git a/gnome-base/gnome-panel/gnome-panel-2.24.1.ebuild b/gnome-base/gnome-panel/gnome-panel-2.24.1.ebuild
new file mode 100644
index 000000000000..69055a311586
--- /dev/null
+++ b/gnome-base/gnome-panel/gnome-panel-2.24.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.24.1.ebuild,v 1.1 2008/11/06 23:44:11 eva Exp $
+
+inherit gnome2
+
+DESCRIPTION="The GNOME panel"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc eds networkmanager"
+
+RDEPEND=">=gnome-base/gnome-desktop-2.12
+	>=x11-libs/pango-1.15.4
+	>=dev-libs/glib-2.16.0
+	>=x11-libs/gtk+-2.13.1
+	>=dev-libs/libgweather-2.24.1
+	dev-libs/libxml2
+	>=gnome-base/libglade-2.5
+	>=gnome-base/libgnome-2.13
+	>=gnome-base/libgnomeui-2.5.4
+	>=gnome-base/libbonoboui-2.1.1
+	>=gnome-base/orbit-2.4
+	>=x11-libs/libwnck-2.19.5
+	>=gnome-base/gconf-2.6.1
+	>=gnome-base/gnome-menus-2.11.1
+	>=gnome-base/libbonobo-2
+	gnome-base/librsvg
+	>=dev-libs/dbus-glib-0.71
+	>=sys-apps/dbus-1.1.2
+	x11-libs/libXau
+	>=x11-libs/cairo-1.0.0
+	eds? ( >=gnome-extra/evolution-data-server-1.6 )
+	networkmanager? ( >=net-misc/networkmanager-0.6 )"
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	>=app-text/gnome-doc-utils-0.3.2
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.40
+	~app-text/docbook-xml-dtd-4.1.2
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		--disable-schemas-install
+		--with-in-process-applets=clock,notification-area,wncklet
+		--disable-polkit
+		$(use_enable networkmanager network-manager)
+		$(use_enable eds)"
+}
+
+pkg_postinst() {
+	local entries="${ROOT}etc/gconf/schemas/panel-default-setup.entries"
+	local gconftool="${ROOT}usr/bin/gconftool-2"
+
+	if [ -e "$entries" ]; then
+		einfo "setting panel gconf defaults..."
+
+		GCONF_CONFIG_SOURCE="$("${gconftool}" --get-default-source | sed "s;:/;:${ROOT};")"
+
+		"${gconftool}" --direct --config-source \
+			"${GCONF_CONFIG_SOURCE}" --load="${entries}"
+	fi
+
+	# Calling this late so it doesn't process the GConf schemas file we already
+	# took care of.
+	gnome2_pkg_postinst
+}