Version bump for Gnome 2.32

(Portage version: 2.1.9.14/cvs/Linux x86_64)

2 files changed, 89 insertions, 1 deletions

diff --git a/app-accessibility/orca/ChangeLog b/app-accessibility/orca/ChangeLog
index 8663595cdab7..32d5dc44bd79 100644
--- a/app-accessibility/orca/ChangeLog
+++ b/app-accessibility/orca/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-accessibility/orca
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/ChangeLog,v 1.89 2010/09/11 18:38:52 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/ChangeLog,v 1.90 2010/10/12 18:17:47 pacho Exp $
+
+*orca-2.32.0 (12 Oct 2010)
+
+  12 Oct 2010; Pacho Ramos <pacho@gentoo.org> +orca-2.32.0.ebuild:
+  Version bump for Gnome 2.32: lots of bugfixes and translation updates.
+  Improves python support but it's still not python3 safe (bug #308261
+  comment #3). Workaround for bug #325611 is also needed at configure phase.
 
   11 Sep 2010; Joseph Jezak <josejx@gentoo.org> orca-2.30.2.ebuild:
   Marked ppc for bug #324077.
diff --git a/app-accessibility/orca/orca-2.32.0.ebuild b/app-accessibility/orca/orca-2.32.0.ebuild
new file mode 100644
index 000000000000..6d079f51f4a5
--- /dev/null
+++ b/app-accessibility/orca/orca-2.32.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/orca-2.32.0.ebuild,v 1.1 2010/10/12 18:17:47 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+PYTHON_DEPEND="2"
+
+inherit gnome2 python
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="http://www.gnome.org/projects/orca/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+# liblouis is not in portage yet
+# it is used to provide contracted braille support
+RDEPEND=">=dev-libs/glib-2.10
+	>=gnome-extra/at-spi-1.24
+	>=gnome-base/orbit-2
+	>=dev-python/pyorbit-2.24
+	>=gnome-base/libbonobo-2.24
+	>=dev-python/libbonobo-python-2.24
+
+	dev-python/pygobject
+	dev-python/pycairo
+	>=dev-python/dbus-python-0.83
+	>=dev-python/pygtk-2.12
+
+	>=dev-python/libwnck-python-2.24
+	>=dev-python/gconf-python-2.24
+	>=dev-python/libgnome-python-2.14
+
+	>=app-accessibility/gnome-speech-0.3.10
+	>=app-accessibility/gnome-mag-0.12.5"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.9"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README TODO"
+	python_set_active_version 2
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+
+	python_convert_shebangs -r 2 .
+}
+
+src_configure() {
+	# FIXME: Workaround for bug #325611 until root cause is found
+	addpredict "$(unset HOME; echo ~)/.gconf"
+	addpredict "$(unset HOME; echo ~)/.gconfd"
+	gnome2_src_configure
+}
+
+src_compile() {
+	# FIXME: Workaround for bug #325611 until root cause is found
+	addpredict "$(unset HOME; echo ~)/.gconf"
+	addpredict "$(unset HOME; echo ~)/.gconfd"
+	gnome2_src_compile
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_mod_optimize "${PN}"
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup "${PN}"
+}