Improve multi abi support

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

3 files changed, 172 insertions, 1 deletions

diff --git a/app-admin/elektra/ChangeLog b/app-admin/elektra/ChangeLog
index 874aec2209b5..8cea86f1af9d 100644
--- a/app-admin/elektra/ChangeLog
+++ b/app-admin/elektra/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-admin/elektra
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/ChangeLog,v 1.15 2013/04/22 10:50:07 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/ChangeLog,v 1.16 2013/04/22 14:17:35 xmw Exp $
+
+*elektra-0.8.3-r2 (22 Apr 2013)
+*elektra-0.7.1-r4 (22 Apr 2013)
+
+  22 Apr 2013; Michael Weber <xmw@gentoo.org> +elektra-0.7.1-r4.ebuild,
+  +elektra-0.8.3-r2.ebuild:
+  Improve multi abi support
 
   22 Apr 2013; Michael Weber <xmw@gentoo.org> -elektra-0.7.1-r2.ebuild,
   -elektra-0.8.3.ebuild:
diff --git a/app-admin/elektra/elektra-0.7.1-r4.ebuild b/app-admin/elektra/elektra-0.7.1-r4.ebuild
new file mode 100644
index 000000000000..e1bf2c573c2c
--- /dev/null
+++ b/app-admin/elektra/elektra-0.7.1-r4.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/elektra-0.7.1-r4.ebuild,v 1.1 2013/04/22 14:17:35 xmw Exp $
+
+EAPI=5
+
+inherit autotools autotools-multilib eutils multilib
+
+DESCRIPTION="universal and secure framework to store config parameters in a hierarchical key-value pair mechanism"
+HOMEPAGE="http://freedesktop.org/wiki/Software/Elektra"
+SRC_URI="ftp://ftp.markus-raab.org/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gcov iconv static-libs test"
+
+RDEPEND="!amd64? ( dev-libs/libxml2 )
+	amd64? (
+		abi_x86_64? ( dev-libs/libxml2 )
+		abi_x86_32? ( app-emulation/emul-linux-x86-baselibs ) )"
+DEPEND="${RDEPEND}
+	!amd64? ( sys-devel/libtool )
+	amd64? ( abi_x86_64? ( sys-devel/libtool ) )
+	iconv? ( virtual/libiconv )
+	!amd64? ( test? ( dev-libs/libxml2[static-libs] ) )"
+
+src_prepare() {
+	einfo 'Removing bundled libltdl'
+	rm -rf libltdl || die
+
+	epatch \
+		"${FILESDIR}"/${P}-test.patch \
+		"${FILESDIR}"/${P}-ltdl.patch \
+		"${FILESDIR}"/${P}-automake-1.12.patch \
+		"${FILESDIR}"/${P}-remove-ddefault-link.patch
+
+	touch config.rpath
+	eautoreconf
+}
+
+src_configure() {
+	# berkeleydb, daemon, fstab, gconf, python do not work
+	# avoid collision with kerberos (bug 403025, 447246)
+	local myeconfargs=(
+		--enable-filesys
+		--enable-hosts
+		--enable-ini
+		--enable-passwd
+		--disable-berkeleydb
+		--disable-fstab
+		--disable-gconf
+		--disable-daemon
+		--enable-cpp
+		--disable-python
+		$(use_enable gcov)
+		$(use_enable iconv)
+		$(use_enable static-libs static)
+		--with-docdir=/usr/share/doc/${PF}
+		--with-develdocdir=/usr/share/doc/${PF}a
+		--includedir=/usr/include/${PN}
+	)
+	autotools-multilib_src_configure
+	dodir /usr/share/man/man3
+}
+
+src_install() {
+	autotools-multilib_src_install
+
+	#avoid collision with allegro (bug 409305)
+	local my_f=""
+	for my_f in $(find "${D}"/usr/share/man/man3 -name "key.3*") ; do
+		mv "${my_f}" "${my_f/key/elektra-key}" || die
+		elog "/usr/share/man/man3/$(basename "${my_f}") installed as $(basename "${my_f/key/elektra-key}")"
+	done
+
+	if ! use static-libs; then
+		find "${D}" -name "*.a" -delete || die
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README TODO
+}
diff --git a/app-admin/elektra/elektra-0.8.3-r2.ebuild b/app-admin/elektra/elektra-0.8.3-r2.ebuild
new file mode 100644
index 000000000000..ee085fc1bcab
--- /dev/null
+++ b/app-admin/elektra/elektra-0.8.3-r2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/elektra-0.8.3-r2.ebuild,v 1.1 2013/04/22 14:17:35 xmw Exp $
+
+EAPI=5
+
+inherit cmake-multilib eutils
+
+DESCRIPTION="universal and secure framework to store config parameters in a hierarchical key-value pair mechanism"
+HOMEPAGE="http://freedesktop.org/wiki/Software/Elektra"
+SRC_URI="ftp://ftp.markus-raab.org/${PN}/releases/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbus doc examples iconv inifile simpleini static-libs syslog tcl test xml yajl"
+
+RDEPEND="!amd64? ( dev-libs/libxml2 )
+	amd64? (
+		abi_x86_64? ( dev-libs/libxml2 )
+		abi_x86_32? ( app-emulation/emul-linux-x86-baselibs ) )"
+DEPEND="${RDEPEND}
+	!amd64? ( sys-devel/libtool )
+	doc? ( app-doc/doxygen )
+	iconv? ( virtual/libiconv )
+	!amd64? ( test? ( dev-libs/libxml2[static-libs] ) )
+	yajl? ( <dev-libs/yajl-2 )"
+
+src_configure() {
+	local my_plugins="ccode;dump;error;fstab;glob;hexcode;hidden;hosts;network;ni;null;path;resolver;struct;success;template;timeofday;tracer;type;validation"
+
+	#fix QA issues with upstream patches
+	epatch "${FILESDIR}/${P}-introduce-attributes.patch"
+	epatch "${FILESDIR}/${P}-fix-yajl-if-user-config.patch"
+
+	#move doc files to correct location
+	sed -e "s/elektra-api/${PF}/" \
+		-i cmake/ElektraCache.cmake || die
+
+	use dbus    && my_plugins+=";dbus"
+	use doc     && my_plugins+=";doc"
+	use iconv   && my_plugins+=";iconv"
+	use inifile && my_plugins+=";simpleini"
+	use syslog  && my_plugins+=";syslog"
+	use tcl     && my_plugins+=";tcl"
+	use xml     && my_plugins+=";xmltool"
+	use yajl    && my_plugins+=";yajl"
+
+	mycmakeargs=(
+		"-DPLUGINS=${my_plugins}"
+		"-DLATEX_COMPILER=OFF"
+		"-DTARGET_CMAKE_FOLDER=share/cmake/Modules"
+		$(cmake-utils_use doc BUILD_DOCUMENTATION)
+		$(cmake-utils_use examples BUILD_EXAMPLES)
+		$(cmake-utils_use static-libs BUILD_STATIC)
+		$(cmake-utils_use test BUILD_TESTING)
+	)
+
+	cmake-multilib_src_configure
+}
+
+src_compile() {
+	dodir /usr/share/man/man3
+	cmake-multilib_src_compile
+}
+
+src_install() {
+	cmake-multilib_src_install
+
+	dodoc doc/{AUTHORS,CHANGES,NEWS,README,todo/TODO}
+
+	if use doc ; then
+		rm -rf "${D}/usr/share/doc/${PF}/man" || die
+		pushd ${CMAKE_BUILD_DIR}/doc/man/man3
+		local my_f
+		for my_f in *.3 ; do
+			newman ${my_f} ${PN}-${my_f}
+			elog "installed /usr/share/man/man3/${my_f} as ${PN}-${my_f}"
+		done
+		popd
+	fi
+}