Fix dependencies. Clean up. Restrict tests since they try to write to home directory without respecting ${HOME}.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 100 insertions, 2 deletions

diff --git a/app-admin/elektra/ChangeLog b/app-admin/elektra/ChangeLog
index 8cea86f1af9d..fdb6c96fe233 100644
--- a/app-admin/elektra/ChangeLog
+++ b/app-admin/elektra/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/elektra
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/ChangeLog,v 1.16 2013/04/22 14:17:35 xmw Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/ChangeLog,v 1.17 2014/06/22 10:01:43 mgorny Exp $
+
+*elektra-0.8.3-r3 (22 Jun 2014)
+
+  22 Jun 2014; Michał Górny <mgorny@gentoo.org> +elektra-0.8.3-r3.ebuild:
+  Fix dependencies. Clean up. Restrict tests since they try to write to home
+  directory without respecting ${HOME}.
 
 *elektra-0.8.3-r2 (22 Apr 2013)
 *elektra-0.7.1-r4 (22 Apr 2013)
diff --git a/app-admin/elektra/elektra-0.8.3-r3.ebuild b/app-admin/elektra/elektra-0.8.3-r3.ebuild
new file mode 100644
index 000000000000..ac940c82bfa9
--- /dev/null
+++ b/app-admin/elektra/elektra-0.8.3-r3.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/elektra-0.8.3-r3.ebuild,v 1.1 2014/06/22 10:01:43 mgorny Exp $
+
+EAPI=5
+
+inherit cmake-multilib eutils
+
+DESCRIPTION="universal and secure framework to store config parameters in a hierarchical key-value pair mechanism"
+HOMEPAGE="http://freedesktop.org/wiki/Software/Elektra"
+SRC_URI="ftp://ftp.markus-raab.org/${PN}/releases/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbus doc examples iconv inifile simpleini static-libs syslog tcl test xml yajl"
+
+RDEPEND=">=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
+	dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
+	iconv? ( >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}] )
+	yajl? (
+		<dev-libs/yajl-2[${MULTILIB_USEDEP}]
+		>=dev-libs/yajl-1.0.11-r1[${MULTILIB_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+	doc? ( app-doc/doxygen )"
+
+# tries to write to user's home directory (and doesn't respect HOME)
+RESTRICT="test"
+
+src_prepare() {
+	#fix QA issues with upstream patches
+	epatch "${FILESDIR}/${P}-introduce-attributes.patch"
+	epatch "${FILESDIR}/${P}-fix-yajl-if-user-config.patch"
+
+	#move doc files to correct location
+	sed -e "s/elektra-api/${PF}/" \
+		-i cmake/ElektraCache.cmake || die
+
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local my_plugins="ccode;dump;error;fstab;glob;hexcode;hidden;hosts;network;ni;null;path;resolver;struct;success;template;timeofday;tracer;type;validation"
+
+	use dbus    && my_plugins+=";dbus"
+	use doc     && my_plugins+=";doc"
+	use iconv   && my_plugins+=";iconv"
+	use inifile && my_plugins+=";simpleini"
+	use syslog  && my_plugins+=";syslog"
+	use tcl     && my_plugins+=";tcl"
+	use xml     && my_plugins+=";xmltool"
+	use yajl    && my_plugins+=";yajl"
+
+	mycmakeargs=(
+		"-DPLUGINS=${my_plugins}"
+		"-DLATEX_COMPILER=OFF"
+		"-DTARGET_CMAKE_FOLDER=share/cmake/Modules"
+		$(multilib_is_native_abi && cmake-utils_use doc BUILD_DOCUMENTATION \
+			|| echo -DBUILD_DOCUMENTATION=OFF)
+		$(multilib_is_native_abi && cmake-utils_use examples BUILD_EXAMPLES \
+			|| echo -DBUILD_EXAMPLES=OFF)
+		$(cmake-utils_use static-libs BUILD_STATIC)
+		$(cmake-utils_use test BUILD_TESTING)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	dodir /usr/share/man/man3
+	cmake-multilib_src_compile
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+
+	if multilib_is_native_abi && use doc; then
+		rm -rf "${D}/usr/share/doc/${PF}/man" || die
+		cd doc/man/man3 || die
+		local my_f
+		for my_f in *.3 ; do
+			newman ${my_f} ${PN}-${my_f}
+			elog "installed /usr/share/man/man3/${my_f} as ${PN}-${my_f}"
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc doc/{AUTHORS,CHANGES,NEWS,README,todo/TODO}
+}