Fix #490992, #494150, #492442, #494532, #494268. Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

7 files changed, 272 insertions, 10 deletions

diff --git a/app-admin/rsyslog/ChangeLog b/app-admin/rsyslog/ChangeLog
index 86103b4e9185..5fec00182000 100644
--- a/app-admin/rsyslog/ChangeLog
+++ b/app-admin/rsyslog/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for app-admin/rsyslog
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.105 2013/12/24 11:33:12 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.106 2013/12/24 12:21:31 ultrabug Exp $
+
+*rsyslog-7.4.7 (24 Dec 2013)
+
+  24 Dec 2013; Ultrabug <ultrabug@gentoo.org> rsyslog-7.2.7.ebuild,
+  rsyslog-7.4.3.ebuild, rsyslog-7.4.4.ebuild, rsyslog-7.4.6.ebuild,
+  +rsyslog-7.4.7.ebuild, metadata.xml:
+  Fix #490992, #494150 thx to Marcin Mirosław & Andrey Volkov. Fix #492442,
+  #494532 using slot operators thx to Thomas D. Add mongodb to IUSE fix #494268
+  thx to Vadim Kuznetsov. Version bump.
 
   24 Dec 2013; Ultrabug <ultrabug@gentoo.org> rsyslog-7.2.7.ebuild,
   rsyslog-7.4.3.ebuild, rsyslog-7.4.4.ebuild, rsyslog-7.4.6.ebuild:
diff --git a/app-admin/rsyslog/metadata.xml b/app-admin/rsyslog/metadata.xml
index d9af5837174e..13c799c04bcb 100644
--- a/app-admin/rsyslog/metadata.xml
+++ b/app-admin/rsyslog/metadata.xml
@@ -3,11 +3,12 @@
 <pkgmetadata>
   <maintainer>
     <email>ultrabug@gentoo.org</email>
-    <name>Alexys Jacob</name>
+    <name>Ultrabug</name>
     <description>Primary Maintainer</description>
   </maintainer>
   <use>
     <flag name="extras">Add support for the UDP spoofing module (omudpspoof) using <pkg>net-libs/libnet</pkg></flag>
+    <flag name="mongodb">Add support for the MongoDB output template module using <pkg>dev-libs/libmongo-client</pkg></flag>
     <flag name="relp">Add support for the Reliable Event Logging Protocol using <pkg>dev-libs/librelp</pkg></flag>
     <flag name="zeromq">Add support for the ZeroMQ input and output plugins using <pkg>net-libs/zeromq</pkg></flag>
   </use>
diff --git a/app-admin/rsyslog/rsyslog-7.2.7.ebuild b/app-admin/rsyslog/rsyslog-7.2.7.ebuild
index 691361dc7b73..e94439820375 100644
--- a/app-admin/rsyslog/rsyslog-7.2.7.ebuild
+++ b/app-admin/rsyslog/rsyslog-7.2.7.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.2.7.ebuild,v 1.7 2013/12/24 11:33:12 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.2.7.ebuild,v 1.8 2013/12/24 12:21:31 ultrabug Exp $
 
 EAPI=4
 AUTOTOOLS_AUTORECONF=yes
@@ -20,6 +20,7 @@ RDEPEND="
 	dev-libs/json-c
 	dev-libs/libee
 	>=dev-libs/libestr-0.1.5
+	dev-libs/libgcrypt
 	dev-libs/liblognorm
 	dbi? ( dev-db/libdbi )
 	extras? ( net-libs/libnet )
@@ -29,7 +30,7 @@ RDEPEND="
 	oracle? ( dev-db/oracle-instantclient-basic )
 	relp? ( >=dev-libs/librelp-1.0.1 )
 	snmp? ( net-analyzer/net-snmp )
-	ssl? ( net-libs/gnutls dev-libs/libgcrypt )
+	ssl? ( net-libs/gnutls )
 	zeromq? ( >=net-libs/zeromq-3 <net-libs/czmq-2 )
 	zlib? ( sys-libs/zlib )"
 DEPEND="${RDEPEND}
diff --git a/app-admin/rsyslog/rsyslog-7.4.3.ebuild b/app-admin/rsyslog/rsyslog-7.4.3.ebuild
index cd2c80f0c316..ff43d6814004 100644
--- a/app-admin/rsyslog/rsyslog-7.4.3.ebuild
+++ b/app-admin/rsyslog/rsyslog-7.4.3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.4.3.ebuild,v 1.5 2013/12/24 11:33:12 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.4.3.ebuild,v 1.6 2013/12/24 12:21:31 ultrabug Exp $
 
 EAPI=4
 AUTOTOOLS_AUTORECONF=yes
@@ -20,6 +20,7 @@ RDEPEND="
 	dev-libs/json-c
 	dev-libs/libee
 	>=dev-libs/libestr-0.1.5
+	dev-libs/libgcrypt
 	dev-libs/liblognorm
 	dbi? ( dev-db/libdbi )
 	extras? ( net-libs/libnet )
@@ -29,7 +30,7 @@ RDEPEND="
 	oracle? ( dev-db/oracle-instantclient-basic )
 	relp? ( >=dev-libs/librelp-1.0.3 )
 	snmp? ( net-analyzer/net-snmp )
-	ssl? ( net-libs/gnutls dev-libs/libgcrypt )
+	ssl? ( net-libs/gnutls )
 	zeromq? ( >=net-libs/zeromq-3 <net-libs/czmq-2 )
 	zlib? ( sys-libs/zlib )"
 DEPEND="${RDEPEND}
diff --git a/app-admin/rsyslog/rsyslog-7.4.4.ebuild b/app-admin/rsyslog/rsyslog-7.4.4.ebuild
index c4c7c4f95a09..2b918a0ef7c9 100644
--- a/app-admin/rsyslog/rsyslog-7.4.4.ebuild
+++ b/app-admin/rsyslog/rsyslog-7.4.4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.4.4.ebuild,v 1.7 2013/12/24 11:33:12 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.4.4.ebuild,v 1.8 2013/12/24 12:21:31 ultrabug Exp $
 
 EAPI=4
 AUTOTOOLS_AUTORECONF=yes
@@ -20,6 +20,7 @@ RDEPEND="
 	dev-libs/json-c
 	dev-libs/libee
 	>=dev-libs/libestr-0.1.5
+	dev-libs/libgcrypt
 	dev-libs/liblognorm
 	dbi? ( dev-db/libdbi )
 	extras? ( net-libs/libnet )
@@ -29,7 +30,7 @@ RDEPEND="
 	oracle? ( dev-db/oracle-instantclient-basic )
 	relp? ( >=dev-libs/librelp-1.0.3 )
 	snmp? ( net-analyzer/net-snmp )
-	ssl? ( net-libs/gnutls dev-libs/libgcrypt )
+	ssl? ( net-libs/gnutls )
 	systemd? ( sys-apps/systemd )
 	zeromq? ( >=net-libs/zeromq-3 <net-libs/czmq-2 )
 	zlib? ( sys-libs/zlib )"
diff --git a/app-admin/rsyslog/rsyslog-7.4.6.ebuild b/app-admin/rsyslog/rsyslog-7.4.6.ebuild
index 857b0f1d47d1..e7fc6bfcd3b4 100644
--- a/app-admin/rsyslog/rsyslog-7.4.6.ebuild
+++ b/app-admin/rsyslog/rsyslog-7.4.6.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.4.6.ebuild,v 1.3 2013/12/24 11:33:12 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.4.6.ebuild,v 1.4 2013/12/24 12:21:31 ultrabug Exp $
 
 EAPI=4
 AUTOTOOLS_AUTORECONF=yes
@@ -20,6 +20,7 @@ RDEPEND="
 	dev-libs/json-c
 	dev-libs/libee
 	>=dev-libs/libestr-0.1.9
+	dev-libs/libgcrypt
 	dev-libs/liblognorm
 	dbi? ( dev-db/libdbi )
 	extras? ( net-libs/libnet )
@@ -29,7 +30,7 @@ RDEPEND="
 	oracle? ( dev-db/oracle-instantclient-basic )
 	relp? ( >=dev-libs/librelp-1.0.3 )
 	snmp? ( net-analyzer/net-snmp )
-	ssl? ( net-libs/gnutls dev-libs/libgcrypt )
+	ssl? ( net-libs/gnutls )
 	systemd? ( sys-apps/systemd )
 	zeromq? ( >=net-libs/zeromq-3 <net-libs/czmq-2 )
 	zlib? ( sys-libs/zlib )"
diff --git a/app-admin/rsyslog/rsyslog-7.4.7.ebuild b/app-admin/rsyslog/rsyslog-7.4.7.ebuild
new file mode 100644
index 000000000000..bf23fc116bb6
--- /dev/null
+++ b/app-admin/rsyslog/rsyslog-7.4.7.ebuild
@@ -0,0 +1,248 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-7.4.7.ebuild,v 1.1 2013/12/24 12:21:31 ultrabug Exp $
+
+EAPI=5
+AUTOTOOLS_AUTORECONF=yes
+
+inherit autotools-utils eutils systemd
+
+DESCRIPTION="An enhanced multi-threaded syslogd with database support and more"
+HOMEPAGE="http://www.rsyslog.com/"
+SRC_URI="http://www.rsyslog.com/files/download/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-3 Apache-2.0"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="dbi debug doc extras kerberos mongodb mysql oracle postgres relp snmp ssl static-libs systemd zeromq zlib"
+
+RDEPEND="
+	dev-libs/json-c:=
+	dev-libs/libee
+	>=dev-libs/libestr-0.1.9
+	dev-libs/libgcrypt:=
+	dev-libs/liblognorm
+	dbi? ( dev-db/libdbi )
+	extras? ( net-libs/libnet )
+	kerberos? ( virtual/krb5 )
+	mongodb? ( dev-libs/libmongo-client )
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql-base )
+	oracle? ( dev-db/oracle-instantclient-basic )
+	relp? ( >=dev-libs/librelp-1.0.3 )
+	snmp? ( net-analyzer/net-snmp )
+	ssl? ( net-libs/gnutls )
+	systemd? ( sys-apps/systemd )
+	zeromq? ( >=net-libs/zeromq-3 <net-libs/czmq-2 )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+BRANCH="7-stable"
+
+# need access to certain device nodes
+RESTRICT="test"
+
+# Maitainer note : open a bug to upstream
+# showing that building in a separate dir fails
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+DOCS=(AUTHORS ChangeLog doc/rsyslog-example.conf)
+
+src_configure() {
+	# Maintainer notes:
+	# * rfc3195 needs a library and development of that library
+	#   is suspended, so we disable it
+	# * About the java GUI:
+	#   The maintainer says there is no real installation support
+	#   for the java GUI, so we disable it for now.
+	# * mongodb : doesnt work with mongo-c-driver ?
+	local myeconfargs=(
+		--enable-cached-man-pages
+		--disable-gui
+		--disable-rfc3195
+		--enable-imdiag
+		--enable-imfile
+		--enable-impstats
+		--enable-imptcp
+		--enable-largefile
+		--enable-mail
+		--enable-mmnormalize
+		--enable-mmjsonparse
+		--enable-mmaudit
+		--enable-mmanon
+		--enable-omprog
+		--enable-omstdout
+		--enable-omuxsock
+		--enable-pmlastmsg
+		--enable-pmrfc3164sd
+		--enable-pmcisconames
+		--enable-pmaixforwardedfrom
+		--enable-pmsnare
+		--enable-sm_cust_bindcdr
+		--enable-unlimited-select
+		--enable-uuid
+		$(use_enable dbi libdbi)
+		$(use_enable debug)
+		$(use_enable debug rtinst)
+		$(use_enable debug diagtools)
+		$(use_enable debug memcheck)
+		$(use_enable debug valgrind)
+		$(use_enable extras omudpspoof)
+		$(use_enable kerberos gssapi-krb5)
+		$(use_enable mongodb ommongodb)
+		$(use_enable mysql)
+		$(use_enable oracle)
+		$(use_enable postgres pgsql)
+		$(use_enable relp)
+		$(use_enable snmp)
+		$(use_enable snmp mmsnmptrapd)
+		$(use_enable ssl gnutls)
+		$(use_enable systemd omjournal)
+		$(use_enable zlib)
+		$(use_enable zeromq imzmq3)
+		$(use_enable zeromq omzmq3)
+		"$(systemd_with_unitdir)"
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	use doc && HTML_DOCS=(doc/)
+	autotools-utils_src_install
+
+	insinto /etc
+	newins "${FILESDIR}/${BRANCH}/${PN}-gentoo.conf" ${PN}.conf
+	newconfd "${FILESDIR}/${BRANCH}/${PN}.confd" ${PN}
+	newinitd "${FILESDIR}/${BRANCH}/${PN}.initd" ${PN}
+	keepdir /var/spool/${PN}
+	keepdir /etc/ssl/${PN}
+	keepdir /etc/${PN}.d
+
+	use static-libs || find "${D}" -name '*.la' -delete || die
+
+	if use mysql; then
+		insinto /usr/share/doc/${PF}/scripts/mysql
+		doins plugins/ommysql/{createDB.sql,contrib/delete_mysql}
+	fi
+
+	if use postgres; then
+		insinto /usr/share/doc/${PF}/scripts/pgsql
+		doins plugins/ompgsql/createDB.sql
+	fi
+
+	insinto /etc/logrotate.d/
+	newins "${FILESDIR}/${BRANCH}/${PN}.logrotate" ${PN}
+}
+
+pkg_postinst() {
+	if use mysql || use postgres; then
+		echo
+		elog "Sample SQL scripts for MySQL & PostgreSQL have been installed to:"
+		elog "  /usr/share/doc/${PF}/scripts"
+	fi
+
+	if use ssl; then
+		echo
+		elog "To create a default CA and certificates for your server and clients, run:"
+		elog "  emerge --config =${PF}"
+		elog "on your logging server. You can run it several times,"
+		elog "once for each logging client. The client certificates will be signed"
+		elog "using the CA certificate generated during the first run."
+	fi
+}
+
+pkg_config() {
+	if ! use ssl ; then
+		einfo "There is nothing to configure for rsyslog unless you"
+		einfo "used USE=ssl to build it."
+		return 0
+	fi
+
+	# Make sure the certificates directory exists
+	CERTDIR="${ROOT}/etc/ssl/${PN}"
+	if [ ! -d "${CERTDIR}" ]; then
+		mkdir "${CERTDIR}" || die
+	fi
+	einfo "Your certificates will be stored in ${CERTDIR}"
+
+	# Create a default CA if needed
+	if [ ! -f "${CERTDIR}/${PN}_ca.cert.pem" ]; then
+		einfo "No CA key and certificate found in ${CERTDIR}, creating them for you..."
+		certtool --generate-privkey \
+			--outfile "${CERTDIR}/${PN}_ca.privkey.pem" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
+
+		cat > "${T}/${PF}.$$" <<- _EOF
+		cn = Portage automated CA
+		ca
+		cert_signing_key
+		expiration_days = 3650
+		_EOF
+
+		certtool --generate-self-signed \
+			--load-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+			--outfile "${CERTDIR}/${PN}_ca.cert.pem" \
+			--template "${T}/${PF}.$$" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
+
+		# Create the server certificate
+		echo
+		einfon "Please type the Common Name of the SERVER you wish to create a certificate for: "
+		read -r CN
+
+		einfo "Creating private key and certificate for server ${CN}..."
+		certtool --generate-privkey \
+			--outfile "${CERTDIR}/${PN}_${CN}.key.pem" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
+
+		cat > "${T}/${PF}.$$" <<- _EOF
+		cn = ${CN}
+		tls_www_server
+		dns_name = ${CN}
+		expiration_days = 3650
+		_EOF
+
+		certtool --generate-certificate \
+			--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
+			--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
+			--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
+			--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+			--template "${T}/${PF}.$$" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
+
+	else
+		einfo "Found existing ${CERTDIR}/${PN}_ca.cert.pem, skipping CA and SERVER creation."
+	fi
+
+	# Create a client certificate
+	echo
+	einfon "Please type the Common Name of the CLIENT you wish to create a certificate for: "
+	read -r CN
+
+	einfo "Creating private key and certificate for client ${CN}..."
+	certtool --generate-privkey \
+		--outfile "${CERTDIR}/${PN}_${CN}.key.pem" &>/dev/null
+	chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
+
+	cat > "${T}/${PF}.$$" <<- _EOF
+	cn = ${CN}
+	tls_www_client
+	dns_name = ${CN}
+	expiration_days = 3650
+	_EOF
+
+	certtool --generate-certificate \
+		--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
+		--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
+		--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
+		--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+		--template "${T}/${PF}.$$" &>/dev/null
+	chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
+
+	rm -f "${T}/${PF}.$$"
+
+	echo
+	einfo "Here is the documentation on how to encrypt your log traffic:"
+	einfo " http://www.rsyslog.com/doc/rsyslog_tls.html"
+}