Add support for the static USE flag, bug #247770.

(Portage version: 2.2_rc23/cvs/Linux x86_64)

2 files changed, 94 insertions, 1 deletions

diff --git a/app-crypt/pinentry/ChangeLog b/app-crypt/pinentry/ChangeLog
index c3900fbe7d11..2d34ba9fc6a2 100644
--- a/app-crypt/pinentry/ChangeLog
+++ b/app-crypt/pinentry/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-crypt/pinentry
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/pinentry/ChangeLog,v 1.91 2009/01/06 21:16:22 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/pinentry/ChangeLog,v 1.92 2009/01/22 19:17:41 swegener Exp $
+
+*pinentry-0.7.5-r1 (22 Jan 2009)
+
+  22 Jan 2009; Sven Wegener <swegener@gentoo.org> +pinentry-0.7.5-r1.ebuild:
+  Add support for the static USE flag, bug #247770.
 
   06 Jan 2009; Sven Wegener <swegener@gentoo.org>
   -files/pinentry-0.7.2-grab.patch, -files/0.7.2-info.patch,
diff --git a/app-crypt/pinentry/pinentry-0.7.5-r1.ebuild b/app-crypt/pinentry/pinentry-0.7.5-r1.ebuild
new file mode 100644
index 000000000000..a6ed7a8d92de
--- /dev/null
+++ b/app-crypt/pinentry/pinentry-0.7.5-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/pinentry/pinentry-0.7.5-r1.ebuild,v 1.1 2009/01/22 19:17:41 swegener Exp $
+
+EAPI="1"
+
+inherit qt3 multilib eutils flag-o-matic
+
+DESCRIPTION="Collection of simple PIN or passphrase entry dialogs which utilize the Assuan protocol"
+HOMEPAGE="http://www.gnupg.org/aegypten/"
+SRC_URI="mirror://gnupg/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="gtk ncurses qt3 caps static"
+
+DEPEND="static? ( sys-libs/ncurses )
+	!static? (
+		gtk? ( =x11-libs/gtk+-2* )
+		ncurses? ( sys-libs/ncurses )
+		qt3? ( x11-libs/qt:3 )
+		!gtk? ( !qt3? ( !ncurses? ( sys-libs/ncurses ) ) )
+	)
+	caps? ( sys-libs/libcap )"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	use static && append-ldflags -static
+
+	if use static && ( use gtk || use qt3 )
+	then
+		ewarn
+		ewarn "The static USE flag is only supported with the ncurses USE flags, disabling the gtk and qt3 USE flags."
+		ewarn
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${P}-grab.patch"
+	epatch "${FILESDIR}/${PN}-gmem.patch"
+}
+
+src_compile() {
+	local myconf=""
+
+	if ! ( use qt3 || use gtk || use ncurses )
+	then
+		myconf="--enable-pinentry-curses --enable-fallback-curses"
+	elif use static
+	then
+		myconf="--enable-pinentry-curses --enable-fallback-curses --disable-pinentry-gtk2 --disable-pinentry-qt"
+	fi
+
+	# Issues finding qt on multilib systems
+	export QTLIB="${QTDIR}/$(get_libdir)"
+
+	econf \
+		--disable-dependency-tracking \
+		--enable-maintainer-mode \
+		--disable-pinentry-gtk \
+		$(use_enable gtk pinentry-gtk2) \
+		$(use_enable qt3 pinentry-qt) \
+		$(use_enable ncurses pinentry-curses) \
+		$(use_enable ncurses fallback-curses) \
+		$(use_with caps libcap) \
+		${myconf} \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die "dodoc failed"
+}
+
+pkg_postinst() {
+	elog "We no longer install pinentry-curses and pinentry-qt SUID root by default."
+	elog "Linux kernels >=2.6.9 support memory locking for unprivileged processes."
+	elog "The soft resource limit for memory locking specifies the limit an"
+	elog "unprivileged process may lock into memory. You can also use POSIX"
+	elog "capabilities to allow pinentry to lock memory. To do so activate the caps"
+	elog "USE flag and add the CAP_IPC_LOCK capability to the permitted set of"
+	elog "your users."
+}