bump to 2.22.1. Misc bug fixes and translation updates.

(Portage version: 2.1.5_rc2)

2 files changed, 91 insertions, 1 deletions

diff --git a/app-editors/gedit/ChangeLog b/app-editors/gedit/ChangeLog
index 1386494849c3..109380ca723d 100644
--- a/app-editors/gedit/ChangeLog
+++ b/app-editors/gedit/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/gedit
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.238 2008/03/29 14:34:45 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.239 2008/04/10 21:29:05 eva Exp $
+
+*gedit-2.22.1 (10 Apr 2008)
+
+  10 Apr 2008; Gilles Dartiguelongue <eva@gentoo.org> +gedit-2.22.1.ebuild:
+  bump to 2.22.1. Misc bug fixes and translation updates.
 
   29 Mar 2008; Gilles Dartiguelongue <eva@gentoo.org> -gedit-2.20.4.ebuild,
   gedit-2.20.4-r1.ebuild, gedit-2.22.0.ebuild:
diff --git a/app-editors/gedit/gedit-2.22.1.ebuild b/app-editors/gedit/gedit-2.22.1.ebuild
new file mode 100644
index 000000000000..6965a6917d80
--- /dev/null
+++ b/app-editors/gedit/gedit-2.22.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.22.1.ebuild,v 1.1 2008/04/10 21:29:05 eva Exp $
+
+inherit gnome2 python eutils autotools
+
+DESCRIPTION="A text editor for the GNOME desktop"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc python spell xattr"
+
+RDEPEND=">=gnome-base/gconf-2
+	xattr? ( sys-apps/attr )
+	>=dev-libs/glib-2.14
+	>=x11-libs/gtk+-2.12
+	>=x11-libs/gtksourceview-2.2
+	>=gnome-base/libgnomeui-2.16
+	>=gnome-base/libglade-2.5.1
+	>=gnome-base/gnome-vfs-2.16
+	spell? (
+		>=app-text/enchant-1.2
+		app-text/iso-codes
+	)
+	python? (
+		>=dev-python/pygobject-2.12
+		>=dev-python/pygtk-2.12
+		>=dev-python/pygtksourceview-2.2
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/pkgconfig-0.9
+	>=app-text/scrollkeeper-0.3.11
+	>=dev-util/intltool-0.35
+	>=app-text/gnome-doc-utils-0.3.2
+	gnome-base/gnome-common"
+# gnome-common needed to eautoreconf
+
+DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"
+
+if [[ "${ARCH}" == "PPC" ]] ; then
+	# HACK HACK HACK: someone fix this garbage
+	MAKEOPTS="${MAKEOPTS} -j1"
+fi
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		$(use_enable python)
+		$(use_enable spell)
+		$(use_enable xattr attr)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Remove symbols that are not meant to be part of the docs, and
+	# break compilation if USE="doc -python" (bug #158638).
+	if use !python && use doc; then
+		epatch "${FILESDIR}"/${PN}-2.16.2-no_python_module_docs.patch
+	fi
+
+	# chown on fbsd doesn't have --reference.  Bug #183691
+	epatch "${FILESDIR}"/${PN}-2.18.1-fbsd.patch
+
+	# Make libattr optional; bug #191989
+	epatch "${FILESDIR}"/${PN}-2.20.3-libattr.patch
+
+	# disable pyc compiling
+	mv "${S}"/py-compile "${S}"/py-compile.orig
+	ln -s $(type -P true) "${S}"/py-compile
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize "${ROOT}usr/$(get_libdir)/gedit-2/plugins"
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins
+}