Fix mail folder corruption, bug 284668. Remove intermediate revision.

(Portage version: 2.2_rc40/cvs/Linux i686)

1 files changed, 49 insertions, 0 deletions

diff --git a/app-emacs/vm/vm-8.0.12-r4.ebuild b/app-emacs/vm/vm-8.0.12-r4.ebuild
new file mode 100644
index 000000000000..6c1a18bdb3e9
--- /dev/null
+++ b/app-emacs/vm/vm-8.0.12-r4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/vm/vm-8.0.12-r4.ebuild,v 1.1 2009/09/12 10:58:18 ulm Exp $
+
+inherit elisp eutils
+
+DESCRIPTION="The VM mail reader for Emacs"
+HOMEPAGE="http://www.nongnu.org/viewmail/"
+SRC_URI="http://download.savannah.nongnu.org/releases/viewmail/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+IUSE="bbdb ssl"
+
+DEPEND="bbdb? ( app-emacs/bbdb )"
+RDEPEND="${DEPEND}
+	ssl? ( net-misc/stunnel )"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${P}-autoload-vm-pine.patch" #246185
+	epatch "${FILESDIR}/${P}-supercite-yank.patch" #256886
+	epatch "${FILESDIR}/${P}-folder-corruption.patch" #284668
+
+	if ! use bbdb; then
+		elog "Excluding vm-pcrisis.el since the \"bbdb\" USE flag is not set."
+		epatch "${FILESDIR}/vm-8.0-no-pcrisis.patch"
+	fi
+}
+
+src_compile() {
+	econf \
+		--with-emacs="emacs" \
+		--with-pixmapdir="${SITEETC}/${PN}" \
+		$(use bbdb && echo "--with-other-dirs=${SITELISP}/bbdb") \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install || die "emake install failed"
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	dodoc NEWS README TODO example.vm || die "dodoc failed"
+}