Re-name and alias completion file to match commands, bug #526246.

(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 81 insertions, 1 deletions

diff --git a/app-misc/booh/ChangeLog b/app-misc/booh/ChangeLog
index 241178880f0a..c11fcb0d3453 100644
--- a/app-misc/booh/ChangeLog
+++ b/app-misc/booh/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/booh
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/booh/ChangeLog,v 1.33 2014/05/07 19:05:40 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/booh/ChangeLog,v 1.34 2014/10/24 18:10:52 mgorny Exp $
+
+*booh-0.9.4-r1 (24 Oct 2014)
+
+  24 Oct 2014; Michał Górny <mgorny@gentoo.org> +booh-0.9.4-r1.ebuild:
+  Re-name and alias completion file to match commands, bug #526246.
 
   07 May 2014; Manuel Rüger <mrueg@gentoo.org> booh-0.9.4.ebuild:
   Remove ruby18 target.
diff --git a/app-misc/booh/booh-0.9.4-r1.ebuild b/app-misc/booh/booh-0.9.4-r1.ebuild
new file mode 100644
index 000000000000..32d24a6ac715
--- /dev/null
+++ b/app-misc/booh/booh-0.9.4-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/booh/booh-0.9.4-r1.ebuild,v 1.1 2014/10/24 18:10:52 mgorny Exp $
+
+EAPI=5
+USE_RUBY="ruby19"
+
+inherit eutils bash-completion-r1 ruby-ng
+
+DESCRIPTION="Static HTML photo album generator"
+HOMEPAGE="http://booh.org/index.html"
+SRC_URI="http://booh.org/packages/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gtk encode exif"
+
+CDEPEND="media-gfx/exiv2
+	gtk? ( >=x11-libs/gtk+-2.8:2 )"
+
+DEPEND="${DEPEND} ${CDEPEND}"
+RDEPEND="${RDEPEND} ${CDEPEND}
+	|| ( media-gfx/imagemagick[jpeg,png] media-gfx/graphicsmagick[jpeg,png] )
+	exif? ( media-gfx/exif )
+	encode? ( media-video/mplayer )"
+
+ruby_add_rdepend "
+	>=dev-ruby/ruby-gettext-0.8.0
+	dev-ruby/ruby-glib2
+	gtk? ( >=dev-ruby/ruby-gtk2-0.12 )"
+
+all_ruby_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.9.2.2-stdc.patch
+
+	# Remove scripts requiring gtk if gtk is not used
+	if ! use gtk; then
+		rm bin/booh bin/booh-classifier bin/booh-fix-whitebalance \
+		bin/booh-gamma-correction || die
+	fi
+	sed -i -e 's/-48x48.png//' desktop/booh-classifier.desktop || die
+	sed -i -e 's/-48x48.png//' desktop/booh.desktop || die
+}
+
+each_ruby_configure() {
+	${RUBY} setup.rb config || die "ruby setup.rb config failed"
+	${RUBY} setup.rb setup || die "ruby setup.rb setup failed"
+	cd ext
+	${RUBY} extconf.rb || die "ruby extconf.rb failed"
+	sed -i -e 's:-Wl,--no-undefined ::' -e 's:-Wl,-R$(libdir)::'\
+		-e 's:-Wl,-R -Wl,$(libdir)::' Makefile || die
+}
+
+each_ruby_compile() {
+	emake -Cext V=1
+}
+
+each_ruby_install() {
+	${RUBY} setup.rb install \
+		--prefix="${D}" || die "ruby setup.rb install failed"
+	cd ext
+	emake install V=1 \
+		DESTDIR="${D}" \
+		libdir="${D}"/$(${RUBY} -rrbconfig -e "puts Config::CONFIG['sitelibdir']") \
+		archdir="${D}"/$({$RUBY} -rrbconfig -e "puts Config::CONFIG['sitearchdir']")
+	cd ..
+}
+
+all_ruby_install() {
+	domenu desktop/booh-classifier.desktop desktop/booh.desktop
+	newicon -s 48 desktop/booh-48x48.png booh.png
+	newbashcomp booh.bash-completion booh-backend
+	bashcomp_alias booh-{backend,classifier}
+	dodoc AUTHORS ChangeLog INTERNALS README VERSION THEMES
+}