Version bump (bug 543896).

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 65 insertions, 1 deletions

diff --git a/app-misc/task/ChangeLog b/app-misc/task/ChangeLog
index a3150fed1292..3152fff543fc 100644
--- a/app-misc/task/ChangeLog
+++ b/app-misc/task/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/task
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.51 2015/02/20 03:42:48 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.52 2015/05/16 19:36:33 radhermit Exp $
+
+*task-2.4.4 (16 May 2015)
+
+  16 May 2015; Tim Harder <radhermit@gentoo.org> +task-2.4.4.ebuild:
+  Version bump (bug 543896).
 
 *task-2.4.1 (20 Feb 2015)
 
diff --git a/app-misc/task/task-2.4.4.ebuild b/app-misc/task/task-2.4.4.ebuild
new file mode 100644
index 000000000000..d5a7d8ae475f
--- /dev/null
+++ b/app-misc/task/task-2.4.4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-2.4.4.ebuild,v 1.1 2015/05/16 19:36:33 radhermit Exp $
+
+EAPI=5
+
+inherit eutils cmake-utils bash-completion-r1
+
+DESCRIPTION="Taskwarrior is a command-line todo list manager"
+HOMEPAGE="http://taskwarrior.org/"
+SRC_URI="http://taskwarrior.org/download/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
+IUSE="gnutls vim-syntax zsh-completion"
+
+DEPEND="sys-libs/readline
+	gnutls? ( net-libs/gnutls )
+	elibc_glibc? ( sys-apps/util-linux )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# use the correct directory locations
+	sed -i "s:/usr/local/bin:${EPREFIX}/usr/bin:" \
+		scripts/add-ons/* || die
+
+	# don't automatically install scripts
+	sed -i '/scripts/d' CMakeLists.txt || die
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_use gnutls GNUTLS)
+		-DTASK_DOCDIR=share/doc/${PF}
+		-DTASK_RCDIR=share/${PN}/rc
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newbashcomp scripts/bash/task.sh task
+
+	if use vim-syntax ; then
+		rm scripts/vim/README
+		insinto /usr/share/vim/vimfiles
+		doins -r scripts/vim/*
+	fi
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins scripts/zsh/*
+	fi
+
+	exeinto /usr/share/${PN}/scripts
+	doexe scripts/add-ons/*
+}