Version bump

(Portage version: 2.2.10/cvs/Linux i686, signed Manifest commit with key 0x3AFFCE974D34BD8C!)

3 files changed, 77 insertions, 1 deletions

diff --git a/app-office/texmacs/ChangeLog b/app-office/texmacs/ChangeLog
index 587061f04666..ef6e910fc56f 100644
--- a/app-office/texmacs/ChangeLog
+++ b/app-office/texmacs/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/texmacs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v 1.111 2014/01/09 07:34:47 grozin Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/ChangeLog,v 1.112 2014/05/01 12:37:09 grozin Exp $
+
+*texmacs-1.99.1 (01 May 2014)
+
+  01 May 2014; Andrey Grozin <grozin@gentoo.org> +texmacs-1.99.1.ebuild,
+  metadata.xml:
+  Version bump
 
 *texmacs-1.0.7.21 (09 Jan 2014)
 
diff --git a/app-office/texmacs/metadata.xml b/app-office/texmacs/metadata.xml
index 097ebee27427..2eeb13f09911 100644
--- a/app-office/texmacs/metadata.xml
+++ b/app-office/texmacs/metadata.xml
@@ -8,5 +8,6 @@
 </maintainer>
 <use>
   <flag name='netpbm'>Add support for <pkg>media-libs/netpbm</pkg></flag>
+  <flag name='pdf'>Add the experimental native pdf export</flag>
 </use>
 </pkgmetadata>
diff --git a/app-office/texmacs/texmacs-1.99.1.ebuild b/app-office/texmacs/texmacs-1.99.1.ebuild
new file mode 100644
index 000000000000..be1e1359ef28
--- /dev/null
+++ b/app-office/texmacs/texmacs-1.99.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmacs/texmacs-1.99.1.ebuild,v 1.1 2014/05/01 12:37:09 grozin Exp $
+
+EAPI=4
+
+inherit autotools eutils fdo-mime gnome2-utils
+
+MY_P=${P/tex/TeX}-src
+
+DESCRIPTION="Wysiwyg text processor with high-quality maths"
+HOMEPAGE="http://www.texmacs.org/"
+SRC_URI="ftp://ftp.texmacs.org/pub/TeXmacs/tmftp/source/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="imlib jpeg netpbm pdf qt4 svg spell"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
+
+RDEPEND="dev-scheme/guile[deprecated]
+	virtual/latex-base
+	app-text/ghostscript-gpl
+	media-libs/freetype
+	x11-libs/libXext
+	x11-apps/xmodmap
+	qt4? ( dev-qt/qtgui:4 )
+	imlib? ( media-libs/imlib2 )
+	jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
+	svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
+	netpbm? ( media-libs/netpbm )
+	spell? ( app-text/aspell )"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# respect LDFLAGS, bug #338459
+	epatch "${FILESDIR}"/${PN}-plugins-1.patch
+
+	# dont update mime and desktop databases and icon cache
+	epatch "${FILESDIR}"/${PN}-updates.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-optimize="${CXXFLAGS}" \
+		$(use_with imlib imlib2) \
+		$(use_enable qt4 qt) \
+		$(use_enable pdf pdf-renderer)
+}
+
+src_install() {
+	default
+	domenu "${FILESDIR}"/TeXmacs.desktop
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}